BitBake User Manual

Lists recipe names (PN values) BitBake does not attempt to build. Instead, BitBake assumes these recipes have already been built.

In OpenEmbedded Core, ASSUME_PROVIDED mostly specifies native tools that should not be built. An example is git-native, which when specified allows for the Git binary from the host to be used rather than building git-native.

The directory in which BitBake executes functions during a recipe's build process.

Specifies a space-delimited list of hosts that the fetcher is allowed to use to obtain the required source code. Following are considerations surrounding this variable:

Using BB_ALLOWED_NETWORKS in conjunction with PREMIRRORS is very useful. Adding the host you want to use to PREMIRRORS results in the source code being fetched from an allowed location and avoids raising an error when a host that is not allowed is in a SRC_URI statement. This is because the fetcher does not attempt to use the host listed in SRC_URI after a successful fetch from the PREMIRRORS occurs.

Specifies the path to a log file into which BitBake's user interface writes output during the build.

Contains the name of the currently running task. The name does not include the do_ prefix.

Defines how BitBake handles situations where an append file (.bbappend) has no corresponding recipe file (.bb). This condition often occurs when layers get out of sync (e.g. oe-core bumps a recipe version and the old recipe no longer exists and the other layer has not been updated to the new version of the recipe yet).

The default fatal behavior is safest because it is the sane reaction given something is out of sync. It is important to realize when your changes are no longer being applied.

The default task to use when none is specified (e.g. with the -c command line option). The task name specified should not include the do_ prefix.

Monitors disk space and available inodes during the build and allows you to control the build based on these parameters.

Disk space monitoring is disabled by default. When setting this variable, use the following form:

     BB_DISKMON_DIRS = "<action>,<dir>,<threshold> [...]"

     where:

        <action> is:
           ABORT:     Immediately abort the build when
                      a threshold is broken.
           STOPTASKS: Stop the build after the currently
                      executing tasks have finished when
                      a threshold is broken.
           WARN:      Issue a warning but continue the
                      build when a threshold is broken.
                      Subsequent warnings are issued as
                      defined by the
                      BB_DISKMON_WARNINTERVAL variable,
                      which must be defined.

        <dir> is:
           Any directory you choose. You can specify one or
           more directories to monitor by separating the
           groupings with a space.  If two directories are
           on the same device, only the first directory
           is monitored.

        <threshold> is:
           Either the minimum available disk space,
           the minimum number of free inodes, or
           both.  You must specify at least one.  To
           omit one or the other, simply omit the value.
           Specify the threshold using G, M, K for Gbytes,
           Mbytes, and Kbytes, respectively. If you do
           not specify G, M, or K, Kbytes is assumed by
           default.  Do not use GB, MB, or KB.
                    

Here are some examples:

     BB_DISKMON_DIRS = "ABORT,${TMPDIR},1G,100K WARN,${SSTATE_DIR},1G,100K"
     BB_DISKMON_DIRS = "STOPTASKS,${TMPDIR},1G"
     BB_DISKMON_DIRS = "ABORT,${TMPDIR},,100K"
                    

The first example works only if you also set the BB_DISKMON_WARNINTERVAL variable. This example causes the build system to immediately abort when either the disk space in ${TMPDIR} drops below 1 Gbyte or the available free inodes drops below 100 Kbytes. Because two directories are provided with the variable, the build system also issues a warning when the disk space in the ${SSTATE_DIR} directory drops below 1 Gbyte or the number of free inodes drops below 100 Kbytes. Subsequent warnings are issued during intervals as defined by the BB_DISKMON_WARNINTERVAL variable.

The second example stops the build after all currently executing tasks complete when the minimum disk space in the ${TMPDIR} directory drops below 1 Gbyte. No disk monitoring occurs for the free inodes in this case.

The final example immediately aborts the build when the number of free inodes in the ${TMPDIR} directory drops below 100 Kbytes. No disk space monitoring for the directory itself occurs in this case.

Defines the disk space and free inode warning intervals.

If you are going to use the BB_DISKMON_WARNINTERVAL variable, you must also use the BB_DISKMON_DIRS variable and define its action as "WARN". During the build, subsequent warnings are issued each time disk space or number of free inodes further reduces by the respective interval.

If you do not provide a BB_DISKMON_WARNINTERVAL variable and you do use BB_DISKMON_DIRS with the "WARN" action, the disk monitoring interval defaults to the following:

     BB_DISKMON_WARNINTERVAL = "50M,5K"
                    

When specifying the variable in your configuration file, use the following form:

     BB_DISKMON_WARNINTERVAL = "<disk_space_interval>,<disk_inode_interval>"

     where:

        <disk_space_interval> is:
           An interval of memory expressed in either
           G, M, or K for Gbytes, Mbytes, or Kbytes,
           respectively. You cannot use GB, MB, or KB.

        <disk_inode_interval> is:
           An interval of free inodes expressed in either
           G, M, or K for Gbytes, Mbytes, or Kbytes,
           respectively. You cannot use GB, MB, or KB.
                    

Here is an example:

     BB_DISKMON_DIRS = "WARN,${SSTATE_DIR},1G,100K"
     BB_DISKMON_WARNINTERVAL = "50M,5K"
                    

These variables cause BitBake to issue subsequent warnings each time the available disk space further reduces by 50 Mbytes or the number of free inodes further reduces by 5 Kbytes in the ${SSTATE_DIR} directory. Subsequent warnings based on the interval occur each time a respective interval is reached beyond the initial warning (i.e. 1 Gbytes and 100 Kbytes).

Specifies the internal whitelist of variables to allow through from the external environment into BitBake's datastore. If the value of this variable is not specified (which is the default), the following list is used: BBPATH, BB_PRESERVE_ENV, BB_ENV_WHITELIST, and BB_ENV_EXTRAWHITE.

Specifies an additional set of variables to allow through (whitelist) from the external environment into BitBake's datastore. This list of variables are on top of the internal list set in BB_ENV_WHITELIST.

When set to "1", causes BitBake's fetcher module to only search PREMIRRORS for files. BitBake will not search the main SRC_URI or MIRRORS.

Contains the filename of the recipe that owns the currently running task. For example, if the do_fetch task that resides in the my-recipe.bb is executing, the BB_FILENAME variable contains "/foo/path/my-recipe.bb".

Causes tarballs of the Git repositories, including the Git metadata, to be placed in the DL_DIR directory. Anyone wishing to create a source mirror would want to enable this variable.

For performance reasons, creating and placing tarballs of the Git repositories is not the default action by BitBake.

     BB_GENERATE_MIRROR_TARBALLS = "1"
                    

Lists variables that are excluded from base configuration checksum, which is used to determine if the cache can be reused.

One of the ways BitBake determines whether to re-parse the main metadata is through checksums of the variables in the datastore of the base configuration data. There are variables that you typically want to exclude when checking whether or not to re-parse and thus rebuild the cache. As an example, you would usually exclude TIME and DATE because these variables are always changing. If you did not exclude them, BitBake would never reuse the cache.

Lists variables that are excluded from checksum and dependency data. Variables that are excluded can therefore change without affecting the checksum mechanism. A common example would be the variable for the path of the build. BitBake's output should not (and usually does not) depend on the directory in which it was built.

Specifies the name of the function to call during the "setscene" part of the task's execution in order to validate the list of task hashes. The function returns the list of setscene tasks that should be executed.

At this point in the execution of the code, the objective is to quickly verify if a given setscene function is likely to work or not. It's easier to check the list of setscene functions in one pass than to call many individual tasks. The returned list need not be completely accurate. A given setscene task can still later fail. However, the more accurate the data returned, the more efficient the build will be.

Used in combination with the ConfigParsed event to trigger re-parsing the base metadata (i.e. all the recipes). The ConfigParsed event can set the variable to trigger the re-parse. You must be careful to avoid recursive loops with this functionality.

Specifies the name of the log files saved into ${T}. By default, the BB_LOGFMT variable is undefined and the log file names get created using the following form:

     log.{task}.{pid}
                    

If you want to force log files to take a specific name, you can set this variable in a configuration file.

Allows BitBake to run at a specific priority (i.e. nice level). System permissions usually mean that BitBake can reduce its priority but not raise it again. See BB_TASK_NICE_LEVEL for additional information.

Disables network access in the BitBake fetcher modules. With this access disabled, any command that attempts to access the network becomes an error.

Disabling network access is useful for testing source mirrors, running builds when not connected to the Internet, and when operating in certain kinds of firewall environments.

The maximum number of tasks BitBake should run in parallel at any one time. If your host development system supports multiple cores, a good rule of thumb is to set this variable to twice the number of cores.

Sets the number of threads BitBake uses when parsing. By default, the number of threads is equal to the number of cores on the system.

Contains a copy of the original external environment in which BitBake was run. The copy is taken before any whitelisted variable values are filtered into BitBake's datastore.

Disables whitelisting and instead allows all variables through from the external environment into BitBake's datastore.

Specifies the name of the executable script files (i.e. run files) saved into ${T}. By default, the BB_RUNFMT variable is undefined and the run file names get created using the following form:

     run.{task}.{pid}
                    

If you want to force run files to take a specific name, you can set this variable in a configuration file.

Contains the name of the currently executing task. The value does not include the "do_" prefix. For example, if the currently executing task is do_config, the value is "config".

Selects the name of the scheduler to use for the scheduling of BitBake tasks. Three options exist:

Defines custom schedulers to import. Custom schedulers need to be derived from the RunQueueScheduler class.

For information how to select a scheduler, see the BB_SCHEDULER variable.

Specifies a function BitBake calls that determines whether BitBake requires a setscene dependency to be met.

When running a setscene task, BitBake needs to know which dependencies of that setscene task also need to be run. Whether dependencies also need to be run is highly dependent on the metadata. The function specified by this variable returns a "True" or "False" depending on whether the dependency needs to be met.

Specifies a function to call that verifies the list of planned task execution before the main task execution happens. The function is called once BitBake has a list of setscene tasks that have run and either succeeded or failed.

The function allows for a task list check to see if they make sense. Even if BitBake was planning to skip a task, the returned value of the function can force BitBake to run the task, which is necessary under certain metadata defined circumstances.

Lists variable flags (varflags) that can be safely excluded from checksum and dependency data for keys in the datastore. When generating checksum or dependency data for keys in the datastore, the flags set against that key are normally included in the checksum.

For more information on varflags, see the "Variable Flags" section.

Defines the name of the signature handler BitBake uses. The signature handler defines the way stamp files are created and handled, if and how the signature is incorporated into the stamps, and how the signature itself is generated.

A new signature handler can be added by injecting a class derived from the SignatureGenerator class into the global namespace.

Defines the behavior of the fetcher when it interacts with source control systems and dynamic source revisions. The BB_SRCREV_POLICY variable is useful when working without a network.

The variable can be set using one of two policies:

Defines the mode used for how timestamps of stamp files are compared. You can set the variable to one of the following modes:

Lists files whose stamp file timestamps are compared when the stamp policy mode is set to "whitelist". For information on stamp policies, see the BB_STAMP_POLICY variable.

Sets a more strict checksum mechanism for non-local URLs. Setting this variable to a value causes BitBake to report an error if it encounters a non-local URL that does not have at least one checksum specified.

Allows adjustment of a task's Input/Output priority. During Autobuilder testing, random failures can occur for tasks due to I/O starvation. These failures occur during various QEMU runtime timeouts. You can use the BB_TASK_IONICE_LEVEL variable to adjust the I/O priority of these tasks.

Set the variable as follows:

     BB_TASK_IONICE_LEVEL = "class.prio"
                    

For class, the default value is "2", which is a best effort. You can use "1" for realtime and "3" for idle. If you want to use realtime, you must have superuser privileges.

For prio, you can use any value from "0", which is the highest priority, to "7", which is the lowest. The default value is "4". You do not need any special privileges to use this range of priority values.

      $ sudo sh -c “echo cfq > /sys/block/device/queu/scheduler
                        

Allows specific tasks to change their priority (i.e. nice level).

You can use this variable in combination with task overrides to raise or lower priorities of specific tasks. For example, on the Yocto Project autobuilder, QEMU emulation in images is given a higher priority as compared to build tasks to ensure that images do not suffer timeouts on loaded systems.

Within an executing task, this variable holds the hash of the task as returned by the currently enabled signature generator.

Controls how verbose BitBake is during builds. If set, shell scripts echo commands and shell script output appears on standard out (stdout).

Specifies if the current context is executing a task. BitBake sets this variable to "1" when a task is being executed. The value is not set when the task is in server context during parsing or event handling.

Allows you to extend a recipe so that it builds variants of the software. Some examples of these variants for recipes from the OpenEmbedded Core metadata are "natives" such as quilt-native, which is a copy of Quilt built to run on the build system; "crosses" such as gcc-cross, which is a compiler built to run on the build machine but produces binaries that run on the target MACHINE; "nativesdk", which targets the SDK machine instead of MACHINE; and "mulitlibs" in the form "multilib:multilib_name".

To build a different variant of the recipe with a minimal amount of code, it usually is as simple as adding the variable to your recipe. Here are two examples. The "native" variants are from the OpenEmbedded Core metadata:

     BBCLASSEXTEND =+ "native nativesdk"
     BBCLASSEXTEND =+ "multilib:multilib_name"
                    

Sets the BitBake debug output level to a specific value as incremented by the -d command line option.

Lists the names of configured layers. These names are used to find the other BBFILE_* variables. Typically, each layer appends its name to this variable in its conf/layer.conf file.

Variable that expands to match files from BBFILES in a particular layer. This variable is used in the conf/layer.conf file and must be suffixed with the name of the specific layer (e.g. BBFILE_PATTERN_emenlow).

Assigns the priority for recipe files in each layer.

This variable is useful in situations where the same recipe appears in more than one layer. Setting this variable allows you to prioritize a layer against other layers that contain the same recipe - effectively letting you control the precedence for the multiple layers. The precedence established through this variable stands regardless of a recipe's version (PV variable). For example, a layer that has a recipe with a higher PV value but for which the BBFILE_PRIORITY is set to have a lower precedence still has a lower precedence.

A larger value for the BBFILE_PRIORITY variable results in a higher precedence. For example, the value 6 has a higher precedence than the value 5. If not specified, the BBFILE_PRIORITY variable is set based on layer dependencies (see the LAYERDEPENDS variable for more information. The default priority, if unspecified for a layer with no dependencies, is the lowest defined priority + 1 (or 1 if no priorities are defined).

List of recipe files BitBake uses to build software.

Contains a space-separated list of all of all files that BitBake's parser included during parsing of the current file.

If set to a value, enables printing the task log when reporting a failed task.

If BBINCLUDELOGS is set, specifies the maximum number of lines from the task log file to print when reporting a failed task. If you do not set BBINCLUDELOGS_LINES, the entire log is printed.

Lists the layers to enable during the build. This variable is defined in the bblayers.conf configuration file in the build directory. Here is an example:

     BBLAYERS = " \
       /home/scottrif/poky/meta \
       /home/scottrif/poky/meta-yocto \
       /home/scottrif/poky/meta-yocto-bsp \
       /home/scottrif/poky/meta-mykernel \
       "

                    

This example enables four layers, one of which is a custom, user-defined layer named meta-mykernel.

Sets the base location where layers are stored. By default, this location is set to ${COREBASE}. This setting is used in conjunction with bitbake-layers layerindex-fetch and tells bitbake-layers where to place the fetched layers.

Prevents BitBake from processing recipes and recipe append files.

You can use the BBMASK variable to "hide" these .bb and .bbappend files. BitBake ignores any recipe or recipe append files that match the expression. It is as if BitBake does not see them at all. Consequently, matching files are not parsed or otherwise used by BitBake.

The value you provide is passed to Python's regular expression compiler. The expression is compared against the full paths to the files. For complete syntax information, see Python's documentation at http://docs.python.org/release/2.3/lib/re-syntax.html.

The following example uses a complete regular expression to tell BitBake to ignore all recipe and recipe append files in the meta-ti/recipes-misc/ directory:

     BBMASK = "meta-ti/recipes-misc/"
                    

If you want to mask out multiple directories or recipes, use the vertical bar to separate the regular expression fragments. This next example masks out multiple directories and individual recipes:

     BBMASK = "meta-ti/recipes-misc/|meta-ti/recipes-ti/packagegroup/"
     BBMASK .= "|.*meta-oe/recipes-support/"
     BBMASK .= "|.*openldap"
     BBMASK .= "|.*opencv"
     BBMASK .= "|.*lzma"
                    

Notice how the vertical bar is used to append the fragments.

Used by BitBake to locate class (.bbclass) and configuration (.conf) files. This variable is analogous to the PATH variable.

If you run BitBake from a directory outside of the build directory, you must be sure to set BBPATH to point to the build directory. Set the variable as you would any environment variable and then run BitBake:

     $ BBPATH="build_directory"
     $ export BBPATH
     $ bitbake target
                    

Points to the server that runs memory-resident BitBake. The variable is only used when you employ memory-resident BitBake.

Allows you to use a configuration file to add to the list of command-line target recipes you want to build.

Allows a single recipe to build multiple versions of a project from a single recipe file. You also able to specify conditional metadata using the OVERRIDES mechanism for a single version or for an optionally named range of versions.

For more information on BBVERSIONS, see the "Variants - Class Extension Mechanism" section.

Used to specify the UI module to use when running BitBake. Using this variable is equivalent to using the -u command-line option.

A name assigned to the build. The name defaults to a datetime stamp of when the build was started but can be defined by the metadata.

The directory in which files checked out of a Bazaar system are stored.

Specifies the directory BitBake uses to store a cache of the metadata so it does not need to be parsed every time BitBake is started.

The directory in which files checked out under the CVS system are stored.

Specifies a weak bias for recipe selection priority.

The most common usage of this is variable is to set it to "-1" within a recipe for a development version of a piece of software. Using the variable in this way causes the stable version of the recipe to build by default in the absence of PREFERRED_VERSION being used to build the development version.

Lists a recipe's build-time dependencies (i.e. other recipe files).

Consider this simple example for two recipes named "a" and "b" that produce similarly named packages. In this example, the DEPENDS statement appears in the "a" recipe:

     DEPENDS = "b"
                    

Here, the dependency is such that the do_configure task for recipe "a" depends on the do_populate_sysroot task of recipe "b". This means anything that recipe "b" puts into sysroot is available when recipe "a" is configuring itself.

For information on runtime dependencies, see the RDEPENDS variable.

A long description for the recipe.

The central download directory used by the build process to store downloads. By default, DL_DIR gets files suitable for mirroring for everything except Git repositories. If you want tarballs of Git repositories, use the BB_GENERATE_MIRROR_TARBALLS variable.

Directs BitBake to exclude a recipe from world builds (i.e. bitbake world). During world builds, BitBake locates, parses and builds all recipes found in every layer exposed in the bblayers.conf configuration file.

To exclude a recipe from a world build using this variable, set the variable to "1" in the recipe.

Contains the command to use when running a shell script in a fakeroot environment. The FAKEROOT variable is obsolete and has been replaced by the other FAKEROOT* variables. See these entries in the glossary for more information.

Lists environment variables to set when executing the command defined by FAKEROOTCMD that starts the bitbake-worker process in the fakeroot environment.

Contains the command that starts the bitbake-worker process in the fakeroot environment.

Lists directories to create before running a task in the fakeroot environment.

Lists environment variables to set when running a task in the fakeroot environment. For additional information on environment variables and the fakeroot environment, see the FAKEROOTBASEENV variable.

Lists environment variables to set when running a task that is not in the fakeroot environment. For additional information on environment variables and the fakeroot environment, see the FAKEROOTENV variable.

Defines the command the BitBake fetcher module executes when running fetch operations. You need to use an override suffix when you use the variable (e.g. FETCHCMD_git or FETCHCMD_svn).

Points at the current file. BitBake sets this variable during the parsing process to identify the file being parsed. BitBake also sets this variable when a recipe is being executed to identify the recipe file.

Specifies directories BitBake uses when searching for patches and files. The "local" fetcher module uses these directories when handling file:// URLs if the file was not found using FILESPATH.

Specifies directories BitBake uses when searching for patches and files. The "local" fetcher module uses these directories when handling file:// URLs. The variable behaves like a shell PATH environment variable. The value is a colon-separated list of directories that are searched left-to-right in order.

The directory in which a local copy of a Git repository is stored when it is cloned.

The directory in which files checked out of a Mercurial system are stored.

Website where more information about the software the recipe is building can be found.

Causes the named class to be inherited at this point during parsing. The variable is only valid in configuration files.

Lists the layers, separated by spaces, upon which this recipe depends. Optionally, you can specify a specific layer version for a dependency by adding it to the end of the layer name with a colon, (e.g. "anotherlayer:3" to be compared against LAYERVERSION_anotherlayer in this case). BitBake produces an error if any dependency is missing or the version numbers do not match exactly (if specified).

You use this variable in the conf/layer.conf file. You must also use the specific layer name as a suffix to the variable (e.g. LAYERDEPENDS_mylayer).

When used inside the layer.conf configuration file, this variable provides the path of the current layer. This variable is not available outside of layer.conf and references are expanded immediately when parsing of the file completes.

Optionally specifies the version of a layer as a single number. You can use this variable within LAYERDEPENDS for another layer in order to depend on a specific version of the layer.

You use this variable in the conf/layer.conf file. You must also use the specific layer name as a suffix to the variable (e.g. LAYERDEPENDS_mylayer).

The list of source licenses for the recipe.

Specifies additional paths from which BitBake gets source code. When the build system searches for source code, it first tries the local download directory. If that location fails, the build system tries locations defined by PREMIRRORS, the upstream source, and then locations specified by MIRRORS in that order.

Allows you to suppress BitBake warnings caused when building two separate recipes that provide the same output.

Bitbake normally issues a warning when building two different recipes where each provides the same output. This scenario is usually something the user does not want. However, cases do exist where it makes sense, particularly in the virtual/* namespace. You can use this variable to suppress BitBake's warnings.

To use the variable, list provider names (e.g. recipe names, virtual/kernel, and so forth).

BitBake uses OVERRIDES to control what variables are overridden after BitBake parses recipes and configuration files.

Following is a simple example that uses an overrides list based on machine architectures:

     OVERRIDES = "arm:x86:mips:powerpc"
                    

You can find information on how to use OVERRIDES in the "Conditional Syntax (Overrides)" section.

The list of packages the recipe creates.

A promise that your recipe satisfies runtime dependencies for optional modules that are found in other recipes. PACKAGES_DYNAMIC does not actually satisfy the dependencies, it only states that they should be satisfied. For example, if a hard, runtime dependency (RDEPENDS) of another package is satisfied during the build through the PACKAGES_DYNAMIC variable, but a package with the module name is never actually produced, then the other package will be broken.

The epoch of the recipe. By default, this variable is unset. The variable is used to make upgrades possible when the versioning scheme changes in some backwards incompatible way.

Specifies the directory BitBake uses to store data that should be preserved between builds. In particular, the data stored is the data that uses BitBake's persistent data API and the data used by the PR Server and PR Service.

Specifies the recipe or package name and includes all version and revision numbers (i.e. eglibc-2.13-r20+svnr15508/ and bash-4.2-r1/).

The recipe name.

The revision of the recipe.

Determines which recipe should be given preference when multiple recipes provide the same item. You should always suffix the variable with the name of the provided item, and you should set it to the PN of the recipe to which you want to give precedence. Some examples:

     PREFERRED_PROVIDER_virtual/kernel ?= "linux-yocto"
     PREFERRED_PROVIDER_virtual/xserver = "xserver-xf86"
     PREFERRED_PROVIDER_virtual/libgl ?= "mesa"
                    

Determines which recipe should be given preference for cases where multiple recipes provide the same item. Functionally, PREFERRED_PROVIDERS is identical to PREFERRED_PROVIDER. However, the PREFERRED_PROVIDERS variable lets you define preferences for multiple situations using the following form:

     PREFERRED_PROVIDERS = "xxx:yyy aaa:bbb ..."
                    

This form is a convenient replacement for the following:

     PREFERRED_PROVIDER_xxx = "yyy"
     PREFERRED_PROVIDER_aaa = "bbb"
                    

If there are multiple versions of recipes available, this variable determines which recipe should be given preference. You must always suffix the variable with the PN you want to select, and you should set PV accordingly for precedence. You can use the "%" character as a wildcard to match any number of characters, which can be useful when specifying versions that contain long revision numbers that could potentially change. Here are two examples:

     PREFERRED_VERSION_python = "2.7.3"
     PREFERRED_VERSION_linux-yocto = "3.10%"
                    

Specifies additional paths from which BitBake gets source code. When the build system searches for source code, it first tries the local download directory. If that location fails, the build system tries locations defined by PREMIRRORS, the upstream source, and then locations specified by MIRRORS in that order.

Typically, you would add a specific server for the build system to attempt before any others by adding something like the following to your configuration:

     PREMIRRORS_prepend = "\
     git://.*/.* http://www.yoctoproject.org/sources/ \n \
     ftp://.*/.* http://www.yoctoproject.org/sources/ \n \
     http://.*/.* http://www.yoctoproject.org/sources/ \n \
     https://.*/.* http://www.yoctoproject.org/sources/ \n"
                    

These changes cause the build system to intercept Git, FTP, HTTP, and HTTPS requests and direct them to the http:// sources mirror. You can use file:// URLs to point to local directories or network shares as well.

A list of aliases by which a particular recipe can be known. By default, a recipe's own PN is implicitly already in its PROVIDES list. If a recipe uses PROVIDES, the additional aliases are synonyms for the recipe and can be useful satisfying dependencies of other recipes during the build as specified by DEPENDS.

Consider the following example PROVIDES statement from a recipe file libav_0.8.11.bb:

     PROVIDES += "libpostproc"
                    

The PROVIDES statement results in the "libav" recipe also being known as "libpostproc".

The network based PR service host and port.

Following is an example of how the PRSERV_HOST variable is set:

     PRSERV_HOST = "localhost:0"
                    

You must set the variable if you want to automatically start a local PR service. You can set PRSERV_HOST to other values to use a remote PR service.

The version of the recipe.

Lists a package's runtime dependencies (i.e. other packages) that must be installed in order for the built package to run correctly. If a package in this list cannot be found during the build, you will get a build error.

Because the RDEPENDS variable applies to packages being built, you should always use the variable in a form with an attached package name. For example, suppose you are building a development package that depends on the perl package. In this case, you would use the following RDEPENDS statement:

     RDEPENDS_${PN}-dev += "perl"
                    

In the example, the development package depends on the perl package. Thus, the RDEPENDS variable has the ${PN}-dev package name as part of the variable.

BitBake supports specifying versioned dependencies. Although the syntax varies depending on the packaging format, BitBake hides these differences from you. Here is the general syntax to specify versions with the RDEPENDS variable:

     RDEPENDS_${PN} = "package (operator version)"
                    

For operator, you can specify the following:

     =
     <
     >
     <=
     >=
                    

For example, the following sets up a dependency on version 1.2 or greater of the package foo:

     RDEPENDS_${PN} = "foo (>= 1.2)"
                    

For information on build-time dependencies, see the DEPENDS variable.

A list of package name aliases that a package also provides. These aliases are useful for satisfying runtime dependencies of other packages both during the build and on the target (as specified by RDEPENDS).

As with all package-controlling variables, you must always use the variable in conjunction with a package name override. Here is an example:

     RPROVIDES_${PN} = "widget-abi-2"
                   

A list of packages that extends the usability of a package being built. The package being built does not depend on this list of packages in order to successfully build, but needs them for the extended usability. To specify runtime dependencies for packages, see the RDEPENDS variable.

BitBake supports specifying versioned recommends. Although the syntax varies depending on the packaging format, BitBake hides these differences from you. Here is the general syntax to specify versions with the RRECOMMENDS variable:

     RRECOMMENDS_${PN} = "package (operator version)"
                    

For operator, you can specify the following:

     =
     <
     >
     <=
     >=
                    

For example, the following sets up a recommend on version 1.2 or greater of the package foo:

     RRECOMMENDS_${PN} = "foo (>= 1.2)"
                    

The section in which packages should be categorized.

The list of source files - local or remote. This variable tells BitBake which bits to pull for the build and how to pull them. For example, if the recipe or append file needs to fetch a single tarball from the Internet, the recipe or append file uses a SRC_URI entry that specifies that tarball. On the other hand, if the recipe or append file needs to fetch a tarball and include a custom file, the recipe or append file needs an SRC_URI variable that specifies all those sources.

The following list explains the available URI protocols:

Here are some additional options worth mentioning:

The date of the source code used to build the package. This variable applies only if the source was fetched from a Source Code Manager (SCM).

The revision of the source code used to build the package. This variable applies only when using Subversion, Git, Mercurial and Bazaar. If you want to build a fixed revision and you want to avoid performing a query on the remote repository every time BitBake parses your recipe, you should specify a SRCREV that is a full revision identifier and not just a tag.

Helps construct valid SRCREV values when multiple source controlled URLs are used in SRC_URI.

The system needs help constructing these values under these circumstances. Each component in the SRC_URI is assigned a name and these are referenced in the SRCREV_FORMAT variable. Consider an example with URLs named "machine" and "meta". In this case, SRCREV_FORMAT could look like "machine_meta" and those names would have the SCM versions substituted into each position. Only one AUTOINC placeholder is added and if needed. And, this placeholder is placed at the start of the returned string.

Specifies the base path used to create recipe stamp files. The path to an actual stamp file is constructed by evaluating this string and then appending additional information.

Specifies the base path used to create recipe stamp files. Unlike the STAMP variable, STAMPCLEAN can contain wildcards to match the range of files a clean operation should remove. BitBake uses a clean operation to remove any other stamps it should be removing when creating a new stamp.

A short summary for the recipe, which is 72 characters or less.

The directory in which files checked out of a Subversion system are stored.

Points to a directory were BitBake places temporary files, which consist mostly of task logs and scripts, when building a particular recipe.

Points to the build directory. BitBake automatically sets this variable.