[meta-freescale] [meta-fsl-demos][PATCH 08/12] packagegroup-fsl-graphics-*: New packagegroups for graphics.
Ann Thornton
ra43240 at freescale.com
Wed Aug 19 06:32:02 PDT 2015
These groupings of packages let the image recipe control the quatitiy of
graphics packages in the image. These packagegroups will only add packages
that are supported on the current MACHINE so a common image recipe can be used
on machines that do not have the same GPU.
-minimal = the least number of packages to be able to support any graphics
-core = only essential graphics packages for a core image
-demos = graphics packages plus graphics demos and examples
-tools = tools commonly used with graphics
-benchmarks = benchmark packages to test graphic capabilities
Signed-off-by: Ann Thornton <ra43240 at freescale.com>
---
.../packagegroup-fsl-graphics-benchmarks.bb | 23 ++++++++
.../packagegroup-fsl-graphics-core.bb | 61 ++++++++++++++++++++++
.../packagegroup-fsl-graphics-demos.bb | 33 ++++++++++++
.../packagegroup-fsl-graphics-minimal.bb | 19 +++++++
.../packagegroup-fsl-graphics-tools.bb | 38 ++++++++++++++
5 files changed, 174 insertions(+)
create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-graphics-benchmarks.bb
create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-graphics-core.bb
create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-graphics-demos.bb
create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-graphics-minimal.bb
create mode 100644 recipes-fsl/packagegroups/packagegroup-fsl-graphics-tools.bb
diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-graphics-benchmarks.bb b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-benchmarks.bb
new file mode 100644
index 0000000..e8d30b7
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-benchmarks.bb
@@ -0,0 +1,23 @@
+# Copyright (C) 2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Package group used by freescale to provide a set of GPU benchmark applications"
+SUMMARY = "Freescale Package group for graphics benchmarks"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+ file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+
+inherit packagegroup
+
+GPU_BENCHMARK = "${@base_contains('DISTRO_FEATURES', 'x11', 'gtkperf','', d)}"
+GL_BENCHMARK = "${@base_contains('DISTRO_FEATURES', 'x11 opengl', 'glmark2 glcompbench','', d)}"
+
+RDEPENDS_${PN} = " \
+ packagegroup-fsl-graphics-core \
+ ${GPU_BENCHMARK} \
+ ${GL_BENCHMARK} \
+"
+RDEPENDS_${PN}_remove_mx6sl = " \
+ glcompbench \
+"
diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-graphics-core.bb b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-core.bb
new file mode 100644
index 0000000..5e34d5d
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-core.bb
@@ -0,0 +1,61 @@
+# Copyright (C) 2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Package group used by freescale to add packages which provides core graphics support"
+SUMMARY = "Freescale Package group for core graphics"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+ file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+inherit packagegroup
+
+# Direct FB packages
+DFB_GRAPHICS_PACKAGES = "${@base_contains('DISTRO_FEATURES', 'directfb', \
+ 'packagegroup-core-full-cmdline packagegroup-core-directfb', '', d)}"
+
+# Wayland packages
+WAYLAND_GRAPHICS_PACKAGES = "${@base_contains('DISTRO_FEATURES', 'x11', '', \
+ base_contains('DISTRO_FEATURES', 'wayland', 'weston weston-init', '', d),d)}"
+
+# X11 packages
+X11_GRAPHICS_PACKAGES = "${@base_contains('DISTRO_FEATURES', 'x11', \
+ 'xorg-minimal-fonts liberation-fonts', '', d)}"
+
+#OpenGL packages
+GL_GRAPHICS_PACKAGES = "${@base_contains('DISTRO_FEATURES', 'opengl', \
+ 'mesa', '', d)}"
+
+RDEPENDS_${PN} = " \
+ ${DFB_GRAPHICS_PACKAGES} \
+ ${WAYLAND_GRAPHICS_PACKAGES} \
+ ${X11_GRAPHICS_PACKAGES} \
+ ${GL_GRAPHICS_PACKAGES} \
+ packagegroup-fsl-graphics-minimal \
+"
+
+SOC_TOOLS_GPU = ""
+SOC_TOOLS_GPU_mx5 = " \
+ ${@base_contains('DISTRO_FEATURES', 'x11', 'amd-gpu-x11-bin-mx51', 'amd-gpu-bin-mx51', d)} \
+"
+
+SOC_TOOLS_GPU_FULL_LIST = " \
+ imx-gpu-viv-g2d \
+ imx-gpu-viv-tools \
+ imx-gpu-viv-tools-apitrace \
+ ${@base_contains('DISTRO_FEATURES', 'x11', \
+ 'xserver-xorg-extension-viv-autohdmi', '', d)} \
+"
+
+SOC_TOOLS_GPU_mx6 = "${SOC_TOOLS_GPU_FULL_LIST}"
+SOC_TOOLS_GPU_remove_mx6ul = "${SOC_TOOLS_GPU_FULL_LIST}"
+SOC_TOOLS_GPU_remove_mx6sl = "imx-gpu-viv-tools-apitrace"
+
+
+DFB_TOOLS_INSTALL = ""
+DFB_TOOLS_INSTALL_mx6 = "${@base_contains('DISTRO_FEATURES', 'directfb', \
+ 'libvivante-dfb-mx6', '', d)}"
+
+RDEPENDS_${PN}_append_imx = " \
+ ${SOC_TOOLS_GPU} \
+ ${DFB_TOOLS_INSTALL} \
+"
diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-graphics-demos.bb b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-demos.bb
new file mode 100644
index 0000000..f84f391
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-demos.bb
@@ -0,0 +1,33 @@
+# Copyright (C) 2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Package group used by freescale to provide set of packages for GPU test"
+SUMMARY = "Freescale Package group for graphics demos"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+ file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+
+inherit packagegroup
+
+# Wayland demos
+WAYLAND_DEMOS = "${@base_contains('DISTRO_FEATURES', 'x11', '', \
+ base_contains('DISTRO_FEATURES', 'wayland', \
+ 'weston-examples gtk+3-demo clutter-1.0-examples', '', d), d)}"
+
+WAYLAND_DEMOS_remove_mx6sl = "clutter-1.0-examples"
+
+# X11 demos that depend on OpenGL
+X11_GL_DEMOS = "${@base_contains('DISTRO_FEATURES', 'x11 opengl','mesa-demos', '', d)}"
+
+RDEPENDS_${PN} = " \
+ packagegroup-fsl-graphics-core \
+ ${WAYLAND_DEMOS} \
+ ${X11_GL_DEMOS} \
+"
+
+GPU_DEMOS = ""
+GPU_DEMOS_mx6 = " imx-gpu-viv-demos fsl-gpu-sdk"
+GPU_DEMOS_remove_mx6ul = " imx-gpu-viv-demos fsl-gpu-sdk"
+
+RDEPENDS_${PN}_append_imx = " ${GPU_DEMOS}"
diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-graphics-minimal.bb b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-minimal.bb
new file mode 100644
index 0000000..1efd071
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-minimal.bb
@@ -0,0 +1,19 @@
+# Copyright (C) 2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Freescale Package group for minimal graphics"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+ file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+
+inherit packagegroup
+
+XSERVER ?= ""
+
+X11_PACKAGES = "${@base_contains('DISTRO_FEATURES', 'x11', \
+ 'twm ${XSERVER} x11-common xclock xterm ', '', d)}"
+
+RDEPENDS_${PN} = " \
+ ${X11_PACKAGES} \
+ "
diff --git a/recipes-fsl/packagegroups/packagegroup-fsl-graphics-tools.bb b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-tools.bb
new file mode 100644
index 0000000..073f517
--- /dev/null
+++ b/recipes-fsl/packagegroups/packagegroup-fsl-graphics-tools.bb
@@ -0,0 +1,38 @@
+# Copyright (C) 2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Freescale Package group for graphics tools"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+ file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+
+inherit packagegroup
+
+RDEPENDS_${PN} = " \
+ evtest \
+ fbset \
+ ${@base_contains('DISTRO_FEATURES', 'x11', 'v4l-utils', '', d)} \
+ "
+
+SOC_GPU_TOOLS_X11 = ""
+SOC_GPU_TOOLS_X11_mx6 = "eglinfo-x11"
+SOC_GPU_TOOLS_X11_remove_mx6ul = "eglinfo-x11"
+SOC_GPU_TOOLS_X11_remove_mx6sl = "eglinfo-x11"
+
+SOC_GPU_TOOLS_FB = ""
+SOC_GPU_TOOLS_FB_mx6 = "eglinfo-fb"
+SOC_GPU_TOOLS_FB_remove_mx6ul = "eglinfo-fb"
+SOC_GPU_TOOLS_FB_remove_mx6sl = "eglinfo-fb"
+
+SOC_GPU_TOOLS_WAYLAND = ""
+
+SOC_GPU_TOOLS_DIRECTFB = ""
+
+RDEPENDS_${PN}_append_imx = " \
+ ${@base_contains("LICENSE_FLAGS_WHITELIST", "commercial", "opencv-samples", "", d)} \
+ ${@base_contains("DISTRO_FEATURES", "x11", "${SOC_GPU_TOOLS_X11}", \
+ base_contains("DISTRO_FEATURES", "wayland", "${SOC_GPU_TOOLS_WAYLAND}", \
+ base_contains("DISTRO_FEATURES", "directfb", "${SOC_GPU_TOOLS_DIRECTFB}", \
+ "${SOC_GPU_TOOLS_FB}", d), d), d)} \
+"
--
1.9.1
More information about the meta-freescale
mailing list