[meta-freescale] [meta-fsl-arm][PATCH 38/41] fmlib: add recipe

[ting.liu at nxp.com]

From: Ting Liu <ting.liu at nxp.com>

Signed-off-by: Ting Liu <ting.liu at nxp.com>
---
 recipes-dpaa/fmlib/fmlib_git.bb | 43 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 recipes-dpaa/fmlib/fmlib_git.bb

diff --git a/recipes-dpaa/fmlib/fmlib_git.bb b/recipes-dpaa/fmlib/fmlib_git.bb
new file mode 100644
index 0000000..effe1aa
--- /dev/null
+++ b/recipes-dpaa/fmlib/fmlib_git.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "Frame Manager User Space Library"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3f16fa8e677e45af3127c5c4bafc3c00"
+
+DEPENDS += "virtual/kernel"
+DEPENDS_virtclass-native = ""
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fmlib.git;branch=sdk-v2.0.x"
+SRCREV = "43fa98fdbf0c697167e415c3f060896d5b482791"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = "DESTDIR=${D} PREFIX=${prefix} LIB_DEST_DIR=${libdir} \
+        CROSS_COMPILE=${TARGET_PREFIX} KERNEL_SRC=${STAGING_KERNEL_DIR}"
+
+TARGET_ARCH_FMLIB = "${DEFAULTTUNE}"
+TARGET_ARCH_FMLIB_e5500 = "ppc32e5500"
+TARGET_ARCH_FMLIB_e6500 = "ppc32e6500"
+TARGET_ARCH_FMLIB_fsl-lsch2 = "arm64a53"
+
+FMLIB_TARGET = "libfm-${TARGET_ARCH_FMLIB}"
+FMLIB_TARGET_t1 = "libfm-${TARGET_ARCH_FMLIB}-fmv3l"
+
+do_compile () {
+    oe_runmake ${FMLIB_TARGET}.a
+}
+
+do_compile_class-native () {
+    :
+}
+
+do_install () {
+    oe_runmake install-${FMLIB_TARGET}
+}
+
+do_install_class-native () {
+    install -d ${D}${includedir}
+    cp -rf ${S}/include/* ${D}${includedir}
+}
+
+BBCLASSEXTEND = "native"
+COMPATIBLE_HOST ?= "(none)"
+COMPATIBLE_HOST_qoriq = ".*"
-- 
1.9.2