[meta-ti] [PATCH 1/2] recipes-bsp: Add recipe for PowerVR SGX544MP2 kernel drivers

[Denys Dmytriyenko]

Ping for addressing Chase's comments?

On Mon, Jul 01, 2013 at 01:41:43PM +0000, Maupin, Chase wrote:
> >-----Original Message-----
> >From: meta-ti-bounces at yoctoproject.org [mailto:meta-ti-
> >bounces at yoctoproject.org] On Behalf Of Hingolikar, Mrinmayee
> >Sent: Monday, July 01, 2013 7:32 AM
> >To: meta-ti at yoctoproject.org
> >Subject: [meta-ti] [PATCH 1/2] recipes-bsp: Add recipe for PowerVR
> >SGX544MP2 kernel drivers
> >
> >* The PowerVR SGX544MP2 is found on omap5 and dra7xx devices. This
> >  recipe adds support for the PowerVR graphics subsystem.
> >
> >Signed-off-by: Mrinmayee Hingolikar <mrinmayee at ti.com>
> >Signed-off-by: Siddharth Heroor <heroor at ti.com>
> >---
> > .../powervr-drivers/omapdrm-pvr_1.9.2253347.bb     |   42
> >++++++++++++++++++++
> > 1 files changed, 42 insertions(+), 0 deletions(-)
> > create mode 100644 recipes-bsp/powervr-drivers/omapdrm-
> >pvr_1.9.2253347.bb
> >
> >diff --git a/recipes-bsp/powervr-drivers/omapdrm-
> >pvr_1.9.2253347.bb b/recipes-bsp/powervr-drivers/omapdrm-
> >pvr_1.9.2253347.bb
> >new file mode 100644
> >index 0000000..edb2682
> >--- /dev/null
> >+++ b/recipes-bsp/powervr-drivers/omapdrm-pvr_1.9.2253347.bb
> >@@ -0,0 +1,42 @@
> >+DESCRIPTION =  "Kernel drivers for the PowerVR SGX chipset found
> >in the omap5 SoCs"
> >+HOMEPAGE = "http://git.ti.com"
> >+LICENSE = "GPLv2"
> >+
> >+LIC_FILES_CHKSUM = "file://MIT-
> >COPYING;md5=8c2810fa6bfdc5ae5c15a0c1ade34054"
> 
> I see an issue with you setting the LICENSE to GPLv2 but having the file you 
> are checking be MIT-COPYING.  This seems wrong.
> 
> >+
> >+inherit module
> >+
> >+SRC_URI = "git://git.ti.com/graphics/omap5-sgx-ddk-
> >linux.git;protocol=git"
> >+S = "${WORKDIR}/git"
> >+
> >+SRCREV = "6668f4ea0bbf7e3df7f72dc2230ab8da1e748b2d"
> >+PR = "${MACHINE_KERNEL_PR}"
> >+
> >+do_compile() {
> >+    cd ${S}/eurasiacon/build/linux2/omap5430_linux
> >+    oe_runmake KERNELDIR="${STAGING_KERNEL_DIR}"
> >+}
> 
> I think you could do a do_compile_prepend here to perform the cd command and 
> set EXTRA_OEMAKE to include the KERNELDIR setting.  That way you don't have 
> to override the entire do_compile function.
> 
> >+
> >+do_install() {
> >+    mkdir -p ${D}/lib/modules/${KERNEL_VERSION}/extra/
> >+    cp
> >${S}/eurasiacon/binary2_omap5430_linux_release/target/kbuild/omapd
> >rm_pvr.ko \
> >+    ${D}/lib/modules/${KERNEL_VERSION}/extra/
> >+}
> 
> Can you not use the default do_install in the module.bbclass?  As long as 
> your makefile can handle modules_install you should be fine here.
> 
> >+
> >+FILES_omapdrm-pvr =
> >"/lib/modules/${KERNEL_VERSION}/extra/omapdrm_pvr.ko"
> 
> The FILES setting in module.bbclass should pick this us out of /lib/modules
> 
> >+RDEPENDS_omapdrm-pvr += "update-modules"
> 
> This RDEPENDS is already part of module.bbclass
> 
> >+
> >+pkg_postinst_omapdrm-pvr () {
> >+#!/bin/sh
> >+if [ -n "$D" ]; then
> >+        exit 1
> >+fi
> >+
> >+depmod -a
> >+update-modules || true
> >+}
> >+
> >+pkg_postrm_omapdrm-pvr () {
> >+#!/bin/sh
> >+update-modules || true
> 
> Why did you need to define these functions?  The module.bbclass that you 
> inherit already has:
> 
> pkg_postinst_append () {
> if [ -z "$D" ]; then
>     depmod -a
>     update-modules || true
> fi
> }
> 
> pkg_postrm_append () {
> update-modules || true
> }
> 
> Won't these work for you?
> 
> >+}
> >--
> >1.7.0.4
> >
> >_______________________________________________
> >meta-ti mailing list
> >meta-ti at yoctoproject.org
> >https://lists.yoctoproject.org/listinfo/meta-ti
> _______________________________________________
> meta-ti mailing list
> meta-ti at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti