[meta-ti] [PATCH 2/2] qmss-lld: Add new recipe for QMSS Module low level driver

[Sam Nelson]

- Provides low level driver and test code for Queue managment subsystem module
- Supports k2h, k2k, k2l k2e devices

Signed-off-by: Sam Nelson <sam.nelson at ti.com>
---
 recipes-bsp/qmss-lld/qmss-lld-test_git.bb |   27 +++++++++++++++++++++++++++
 recipes-bsp/qmss-lld/qmss-lld.inc         |   15 +++++++++++++++
 recipes-bsp/qmss-lld/qmss-lld_git.bb      |   20 ++++++++++++++++++++
 3 files changed, 62 insertions(+)
 create mode 100755 recipes-bsp/qmss-lld/qmss-lld-test_git.bb
 create mode 100644 recipes-bsp/qmss-lld/qmss-lld.inc
 create mode 100755 recipes-bsp/qmss-lld/qmss-lld_git.bb

diff --git a/recipes-bsp/qmss-lld/qmss-lld-test_git.bb b/recipes-bsp/qmss-lld/qmss-lld-test_git.bb
new file mode 100755
index 0000000..438d840
--- /dev/null
+++ b/recipes-bsp/qmss-lld/qmss-lld-test_git.bb
@@ -0,0 +1,27 @@
+DESCRIPTION = "TI QMSS low level driver unit test and example binaries"
+COMPATIBLE_MACHINE = "keystone"
+
+DEPENDS="common-csl-ip rm-lld cppi-lld qmss-lld"
+
+include qmss-lld.inc
+
+CHOICELIST = "yes no"
+
+do_compile () {
+#   Now build the lld in the updated directory
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 clean PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" QMSS_SRC_DIR=${S}
+		for choice in ${CHOICELIST}
+		do
+			make -f makefile_armv7 tests examples PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" QMSS_SRC_DIR=${S} USEDYNAMIC_LIB="$choice"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 installbin PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" QMSS_SRC_DIR=${S} INSTALL_BIN_BASE_DIR=${D}${bindir}
+	done
+}
diff --git a/recipes-bsp/qmss-lld/qmss-lld.inc b/recipes-bsp/qmss-lld/qmss-lld.inc
new file mode 100644
index 0000000..87499cc
--- /dev/null
+++ b/recipes-bsp/qmss-lld/qmss-lld.inc
@@ -0,0 +1,15 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/drv/qmss/COPYING.txt;md5=e8f6789acdcda76d02ed9203fc2e603d"
+
+BRANCH ="master"
+SRC_URI = "git://git.ti.com/keystone-rtos/qmss-lld.git;destsuffix=git/ti/drv/qmss;protocol=git;branch=${BRANCH}"
+
+# commit ID corresponding to DEV.QMSS_LLD.02.01.00.06
+SRCREV = "661fff76530fd56cf7550f76c7b7a541ea18fda8"
+PV = "02.01.00.06"
+PR = "r0"
+
+DEVICELIST = "k2h k2k k2l k2e"
+
+BASEDIR = "${WORKDIR}/git"
+S = "${BASEDIR}/ti/drv/qmss"
diff --git a/recipes-bsp/qmss-lld/qmss-lld_git.bb b/recipes-bsp/qmss-lld/qmss-lld_git.bb
new file mode 100755
index 0000000..9d2f547
--- /dev/null
+++ b/recipes-bsp/qmss-lld/qmss-lld_git.bb
@@ -0,0 +1,20 @@
+DESCRIPTION = "TI QMSS low level driver library"
+COMPATIBLE_MACHINE = "keystone"
+
+DEPENDS="common-csl-ip rm-lld"
+
+include qmss-lld.inc
+
+do_compile () {
+#   Now build the lld
+    make -f makefile_armv7 clean PDK_INSTALL_PATH=${STAGING_INCDIR}
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 lib PDK_INSTALL_PATH=${STAGING_INCDIR}  DEVICE="${device}"
+	done
+
+}
+
+do_install () {
+    make -f makefile_armv7 install PDK_INSTALL_PATH=${STAGING_INCDIR} INSTALL_INC_BASE_DIR=${D}${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir}
+}
-- 
1.7.9.5