[meta-ti] Sam Nelson : cppi-lld: Add new recipe for CPPI Module low level driver

[Arago Project git]

Module: meta-ti
Branch: master
Commit: 70664faa8da48c0c8cfed96c89c038017b8bfea1
URL:    http://arago-project.org/git/meta-ti.git?a=commit;h=70664faa8da48c0c8cfed96c89c038017b8bfea1

Author: Sam Nelson <sam.nelson at ti.com>
Date:   Wed Dec 17 00:12:10 2014 +0000

cppi-lld: Add new recipe for CPPI Module low level driver

- Provides low level driver and test code for Communications port programming
  interface module
- Supports k2h, k2k, k2l k2e devices

Signed-off-by: Sam Nelson <sam.nelson at ti.com>
Signed-off-by: Denys Dmytriyenko <denys at ti.com>

---

 recipes-bsp/cppi-lld/cppi-lld-test_git.bb |   26 ++++++++++++++++++++++++++
 recipes-bsp/cppi-lld/cppi-lld.inc         |   15 +++++++++++++++
 recipes-bsp/cppi-lld/cppi-lld_git.bb      |   19 +++++++++++++++++++
 3 files changed, 60 insertions(+), 0 deletions(-)

diff --git a/recipes-bsp/cppi-lld/cppi-lld-test_git.bb b/recipes-bsp/cppi-lld/cppi-lld-test_git.bb
new file mode 100755
index 0000000..871546e
--- /dev/null
+++ b/recipes-bsp/cppi-lld/cppi-lld-test_git.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "TI CPPI low level driver unit test and example binaries"
+COMPATIBLE_MACHINE = "keystone"
+DEPENDS = "common-csl-ip rm-lld cppi-lld qmss-lld"
+
+include cppi-lld.inc
+
+CHOICELIST = "yes no"
+
+do_compile () {
+#   Now build the lld in the updated directory
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 clean PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" CPPI_SRC_DIR=${S}
+		for choice in ${CHOICELIST}
+		do
+			make -f makefile_armv7 tests examples PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" CPPI_SRC_DIR=${S} USEDYNAMIC_LIB="$choice"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+do
+	make -f makefile_armv7 installbin PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" CPPI_SRC_DIR=${S} INSTALL_BIN_BASE_DIR=${D}${bindir}
+	done
+}
diff --git a/recipes-bsp/cppi-lld/cppi-lld.inc b/recipes-bsp/cppi-lld/cppi-lld.inc
new file mode 100644
index 0000000..d26adc5
--- /dev/null
+++ b/recipes-bsp/cppi-lld/cppi-lld.inc
@@ -0,0 +1,15 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/drv/cppi/COPYING.txt;md5=e8f6789acdcda76d02ed9203fc2e603d"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/keystone-rtos/cppi-lld.git;destsuffix=git/ti/drv/cppi;protocol=git;branch=${BRANCH}"
+
+# Below Commit ID corresponds to "DEV.CPPI_LLD.02.01.00.06"
+SRCREV = "4c6c0a857786c49d8003453d3bc7c3c97ff4f5a4"
+PV = "02.01.00.06"
+PR = "r0"
+
+DEVICELIST = "k2h k2k k2l k2e"
+
+BASEDIR = "${WORKDIR}/git"
+S = "${BASEDIR}/ti/drv/cppi"
diff --git a/recipes-bsp/cppi-lld/cppi-lld_git.bb b/recipes-bsp/cppi-lld/cppi-lld_git.bb
new file mode 100755
index 0000000..bb2028b
--- /dev/null
+++ b/recipes-bsp/cppi-lld/cppi-lld_git.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "TI CPPI Module low level driver"
+COMPATIBLE_MACHINE = "keystone"
+
+DEPENDS = "common-csl-ip rm-lld qmss-lld"
+
+include cppi-lld.inc
+
+do_compile () {
+#   Now build the lld in the updated directory
+	make -f makefile_armv7 clean PDK_INSTALL_PATH=${STAGING_INCDIR}
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 lib PDK_INSTALL_PATH=${STAGING_INCDIR}  DEVICE="${device}" 
+	done
+}
+
+do_install () {
+	make -f makefile_armv7 install PDK_INSTALL_PATH=${STAGING_INCDIR} INSTALL_INC_BASE_DIR=${D}/${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir}
+}