[meta-ti] [PATCH 1/2] pa-lld: Add recipes for PA low level driver and test code

[Sam Nelson]

- Provides low level driver for Packet accelerator module
- Supports k2h, k2k, k2l & k2e devices

Signed-off-by: Sam Nelson <sam.nelson at ti.com>
---
 recipes-bsp/pa-lld/pa-lld-test_git.bb |   28 ++++++++++++++++++++++++++++
 recipes-bsp/pa-lld/pa-lld.inc         |   15 +++++++++++++++
 recipes-bsp/pa-lld/pa-lld_git.bb      |   15 +++++++++++++++
 3 files changed, 58 insertions(+)
 create mode 100644 recipes-bsp/pa-lld/pa-lld-test_git.bb
 create mode 100644 recipes-bsp/pa-lld/pa-lld.inc
 create mode 100644 recipes-bsp/pa-lld/pa-lld_git.bb

diff --git a/recipes-bsp/pa-lld/pa-lld-test_git.bb b/recipes-bsp/pa-lld/pa-lld-test_git.bb
new file mode 100644
index 0000000..b70dadd
--- /dev/null
+++ b/recipes-bsp/pa-lld/pa-lld-test_git.bb
@@ -0,0 +1,28 @@
+DESCRIPTION = "TI PA LLD unit test and example binaries"
+
+DEPENDS = "common-csl-ip pa-lld cppi-lld qmss-lld sa-lld"
+
+include pa-lld.inc
+
+DEVICELIST = "k2h k2k k2l k2e"
+
+CHOICELIST = "yes no"
+
+do_compile () {
+# Now build the lld unit test examples
+	for device in ${DEVICELIST}
+	do
+	make -f makefile_armv7 clean PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" PA_SRC_DIR=${S}
+		for choice in ${CHOICELIST}
+		do
+			make -f makefile_armv7 tests examples PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" PA_SRC_DIR=${S} USEDYNAMIC_LIB="$choice"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 installbin PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" PA_SRC_DIR=${S} INSTALL_BIN_BASE_DIR=${D}${bindir}
+	done
+}
diff --git a/recipes-bsp/pa-lld/pa-lld.inc b/recipes-bsp/pa-lld/pa-lld.inc
new file mode 100644
index 0000000..e93ce15
--- /dev/null
+++ b/recipes-bsp/pa-lld/pa-lld.inc
@@ -0,0 +1,15 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/drv/pa/COPYING.txt;md5=e8f6789acdcda76d02ed9203fc2e603d"
+
+COMPATIBLE_MACHINE = "keystone"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/keystone-rtos/pa-lld.git;destsuffix=git/ti/drv/pa;protocol=git;branch=${BRANCH}"
+
+# Below Commit ID corresponds to "DEV.PA_LLD.03.00.01.01"
+SRCREV = "55207930b4491f33776f2c4c2c0707a73c69314c"
+PV = "03.00.01.01"
+PR = "r0"
+
+BASEDIR = "${WORKDIR}/git"
+S = "${BASEDIR}/ti/drv/pa"
diff --git a/recipes-bsp/pa-lld/pa-lld_git.bb b/recipes-bsp/pa-lld/pa-lld_git.bb
new file mode 100644
index 0000000..63e34ad
--- /dev/null
+++ b/recipes-bsp/pa-lld/pa-lld_git.bb
@@ -0,0 +1,15 @@
+DESCRIPTION = "TI PA LLD library"
+
+DEPENDS = "common-csl-ip rm-lld"
+
+include pa-lld.inc
+
+do_compile () {
+#   Now build the lld in the updated directory
+	make -f makefile_armv7 DEVICE=k2h clean lib PDK_INSTALL_PATH=${STAGING_INCDIR}
+	make -f makefile_armv7 DEVICE=k2l lib PDK_INSTALL_PATH=${STAGING_INCDIR}
+}
+
+do_install () {
+	make -f makefile_armv7 install PDK_INSTALL_PATH=${STAGING_INCDIR} INSTALL_INC_BASE_DIR=${D}${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir}
+}
-- 
1.7.9.5