[meta-ti] [PATCH] srio-lld: Add recipe for srio peripheral low level driver

[Sam Nelson]

- Provides user space low level driver for srio peripheral
- Devices supported k2h & k2k

Signed-off-by: Sam Nelson <sam.nelson at ti.com>
---
 recipes-bsp/srio-lld/srio-lld-test_git.bb |   27 +++++++++++++++++++++++++++
 recipes-bsp/srio-lld/srio-lld.inc         |   16 ++++++++++++++++
 recipes-bsp/srio-lld/srio-lld_git.bb      |   19 +++++++++++++++++++
 3 files changed, 62 insertions(+)
 create mode 100644 recipes-bsp/srio-lld/srio-lld-test_git.bb
 create mode 100644 recipes-bsp/srio-lld/srio-lld.inc
 create mode 100644 recipes-bsp/srio-lld/srio-lld_git.bb

diff --git a/recipes-bsp/srio-lld/srio-lld-test_git.bb b/recipes-bsp/srio-lld/srio-lld-test_git.bb
new file mode 100644
index 0000000..7cf254e
--- /dev/null
+++ b/recipes-bsp/srio-lld/srio-lld-test_git.bb
@@ -0,0 +1,27 @@
+DESCRIPTION = "TI SRIO peripheral low level driver unit test and example binaries"
+COMPATIBLE_MACHINE = "keystone"
+DEPENDS="common-csl-ip rm-lld cppi-lld qmss-lld srio-lld cmem"
+
+include srio-lld.inc
+
+CHOICELIST = "yes no"
+
+do_compile () {
+#   Now build the lld in the updated directory
+	for device in ${DEVICELIST}
+	do
+		oe_runmake clean DEVICE="$device" SRIO_SRC_DIR=${S}
+		for choice in ${CHOICELIST}
+		do
+			oe_runmake tests DEVICE="$device" SRIO_SRC_DIR=${S} USEDYNAMIC_LIB="$choice"
+			oe_runmake examples DEVICE="$device" SRIO_SRC_DIR=${S} USEDYNAMIC_LIB="$choice"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		oe_runmake installbin DEVICE="$device" SRIO_SRC_DIR=${S} INSTALL_BIN_BASE_DIR=${D}${bindir}
+	done
+}
diff --git a/recipes-bsp/srio-lld/srio-lld.inc b/recipes-bsp/srio-lld/srio-lld.inc
new file mode 100644
index 0000000..1ae2128
--- /dev/null
+++ b/recipes-bsp/srio-lld/srio-lld.inc
@@ -0,0 +1,16 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/drv/srio/srio_drv.h;beginline=1;endline=41;md5=469096088e072d883ff7eef301b34093"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/keystone-rtos/srio-lld.git;destsuffix=git/ti/drv/srio;protocol=git;branch=${BRANCH}"
+
+# commit ID corresponding to DEV.SRIO_LLD.02.00.00.11
+SRCREV = "2d0efea281222055b3b828c79e57102edaae9db7"
+PV = "02.00.00.11"
+
+DEVICELIST = "k2h k2k"
+
+BASEDIR = "${WORKDIR}/git"
+S = "${BASEDIR}/ti/drv/srio"
+
+EXTRA_OEMAKE = "-f makefile_armv7 PDK_INSTALL_PATH=${STAGING_INCDIR}"
diff --git a/recipes-bsp/srio-lld/srio-lld_git.bb b/recipes-bsp/srio-lld/srio-lld_git.bb
new file mode 100644
index 0000000..9ff845b
--- /dev/null
+++ b/recipes-bsp/srio-lld/srio-lld_git.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "TI SRIO peripheral low level driver"
+COMPATIBLE_MACHINE = "keystone"
+
+DEPENDS="common-csl-ip rm-lld cppi-lld"
+
+include srio-lld.inc
+
+do_compile () {
+#   Now build the lld
+	oe_runmake clean
+	for device in ${DEVICELIST}
+	do
+		oe_runmake lib DEVICE="${device}"
+	done
+}
+
+do_install () {
+	oe_runmake install INSTALL_INC_BASE_DIR=${D}${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir}
+}
-- 
1.7.9.5