[meta-ti] [PATCH 4/4] common-csl-ip-rtos: Add CSL RTOS package.

[Denys Dmytriyenko]

Ack

Are all the dependencies ready for this?

Should all the files be added to ${PN}-dev?


On Wed, May 27, 2015 at 10:10:38AM -0400, Jacob Stiffler wrote:
> Signed-off-by: Jacob Stiffler <j-stiffler at ti.com>
> ---
>  .../common-csl-ip/common-csl-ip-rtos_git.bb        |   33 ++++++++++++++++++++
>  1 file changed, 33 insertions(+)
>  create mode 100644 recipes-bsp/common-csl-ip/common-csl-ip-rtos_git.bb
> 
> diff --git a/recipes-bsp/common-csl-ip/common-csl-ip-rtos_git.bb b/recipes-bsp/common-csl-ip/common-csl-ip-rtos_git.bb
> new file mode 100644
> index 0000000..5d4a552
> --- /dev/null
> +++ b/recipes-bsp/common-csl-ip/common-csl-ip-rtos_git.bb
> @@ -0,0 +1,33 @@
> +require common-csl-ip.inc
> +
> +require recipes-ti/includes/ti-paths.inc
> +require recipes-ti/includes/ti-staging.inc
> +
> +DEPENDS = "ti-xdctools ti-cgt6x-native ti-sysbios"
> +
> +S = "${WORKDIR}/ti/csl"
> +
> +export C6X_GEN_INSTALL_PATH="${STAGING_DIR_NATIVE}/usr"
> +export XDCCGROOT="${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
> +export XDCPATH="${XDCCGROOT}/include;${XDC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages"
> +
> +do_configure() {
> +    sed -i "s/\ \"\.\\\\\\\\\"\ +//" src/Module.xs
> +    find -name "*.xs" -exec sed -i "s/ofd6x\.exe/ofd6x/" {} \;
> +    find -name "*.xs" -exec sed -i "s/sectti\.exe/sectti/" {} \;
> +    find -name "*.xs" -exec sed -i "/\.chm/d" {} \;
> +    find -name "*.xs" -exec sed -i "s/pasm\_dos/pasm\_linux/" {} \;
> +}
> +
> +do_compile() {
> +    ${XDC_INSTALL_DIR}/xdc .make
> +    ${XDC_INSTALL_DIR}/xdc clean
> +    ${XDC_INSTALL_DIR}/xdc release
> +}
> +
> +do_install () {
> +    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    find -name "*.tar" -exec tar xf {} -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages \;
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
> -- 
> 1.7.9.5
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti