[meta-ti] [PATCH] icss-emac-lld*: upstream version 1.0.0.7C with recipes for linux user space

[Denys Dmytriyenko]

On Tue, Jul 11, 2017 at 03:09:28PM -0400, Hongmei Gou wrote:
> Signed-off-by: Hongmei Gou <h-gou at ti.com>
> ---
>  .../icss-emac-lld/icss-emac-lld-test_git.bb        | 47 ++++++++++++++++++++++
>  recipes-bsp/icss-emac-lld/icss-emac-lld.inc        | 22 ++++++++++
>  recipes-bsp/icss-emac-lld/icss-emac-lld_git.bb     | 26 ++++++++++++
>  3 files changed, 95 insertions(+)
>  create mode 100644 recipes-bsp/icss-emac-lld/icss-emac-lld-test_git.bb
>  create mode 100644 recipes-bsp/icss-emac-lld/icss-emac-lld.inc
>  create mode 100644 recipes-bsp/icss-emac-lld/icss-emac-lld_git.bb
> 
> diff --git a/recipes-bsp/icss-emac-lld/icss-emac-lld-test_git.bb b/recipes-bsp/icss-emac-lld/icss-emac-lld-test_git.bb
> new file mode 100644
> index 0000000..f62bf33
> --- /dev/null
> +++ b/recipes-bsp/icss-emac-lld/icss-emac-lld-test_git.bb
> @@ -0,0 +1,47 @@
> +DESCRIPTION = "TI ICSS-EMAC low level driver tests"
> +
> +DEPENDS="common-csl-ip pruss-lld icss-emac-lld osal"
> +
> +DEPENDS_append_ti33x = " starterware"
> +DEPENDS_append_ti43x = " starterware"
> +
> +include icss-emac-lld.inc
> +
> +PR = "${INC_PR}.0"
> +
> +COMPATIBLE_MACHINE = "am57xx-evm|ti33x|ti43x"

What about am57xx-hs-evm? Or dra7xx-evm?


> +
> +EXTRA_OEMAKE += "-f makefile_armv7 PDK_INSTALL_PATH=${STAGING_INCDIR} ICSS_EMAC_SRC_DIR=${S}"
> +
> +do_compile_am57xx-evm () {
> +#   Build the tests
> +    oe_runmake tests DEVICE="am571x" TARGET="SOC_AM571x"
> +    oe_runmake clean
> +    oe_runmake tests DEVICE="am572x" TARGET="SOC_AM572x"

Wouldn't this remove the am571x binaries before building am572x ones?


> +}
> +
> +do_compile_ti33x () {
> +#   Build the tests
> +    oe_runmake tests DEVICE="am335x" TARGET="SOC_AM335x"
> +}
> +
> +do_compile_ti43x () {
> +#   Build the tests
> +    oe_runmake tests DEVICE="am437x" TARGET="SOC_AM437x"
> +}
> +
> +do_install_am57xx-evm () {
> +#   Install the binary
> +    oe_runmake installbin INSTALL_BIN_BASE_DIR=${D}${bindir} DEVICE="am571x" TARGET="SOC_AM571x"
> +    oe_runmake installbin INSTALL_BIN_BASE_DIR=${D}${bindir} DEVICE="am572x" TARGET="SOC_AM572x"
> +}
> +
> +do_install_ti33x () {
> +#   Install the binary
> +    oe_runmake installbin INSTALL_BIN_BASE_DIR=${D}${bindir} DEVICE="am335x" TARGET="SOC_AM335x"
> +}
> +
> +do_install_ti43x () {
> +#   Install the binary
> +    oe_runmake installbin INSTALL_BIN_BASE_DIR=${D}${bindir} DEVICE="am437x" TARGET="SOC_AM437x"
> +}
> diff --git a/recipes-bsp/icss-emac-lld/icss-emac-lld.inc b/recipes-bsp/icss-emac-lld/icss-emac-lld.inc
> new file mode 100644
> index 0000000..8e2ffd4
> --- /dev/null
> +++ b/recipes-bsp/icss-emac-lld/icss-emac-lld.inc
> @@ -0,0 +1,22 @@
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://icss_emacDrv.h;beginline=1;endline=40;md5=88d270788c1d8516511304f11a28586d"
> +
> +COMPATIBLE_MACHINE = "ti33x|ti43x|am57xx-evm|k2g-evm"

AM5 HS and K2G HS platforms will be missed.


> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +ICSS_EMAC_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/icss-emac.git"
> +ICSS_EMAC_LLD_GIT_PROTOCOL = "git"
> +ICSS_EMAC_LLD_GIT_BRANCH = "master"
> +ICSS_EMAC_LLD_GIT_DESTSUFFIX = "git/ti/drv/icss_emac"
> +
> +# Below commit ID corresponds to "DEV.ICSS_EMAC_LLD.01.00.00.07C"
> +ICSS_EMAC_LLD_SRCREV = "08cb0540eeab7721fe82b603cb6285393f314117"
> +
> +BRANCH = "${ICSS_EMAC_LLD_GIT_BRANCH}"
> +SRC_URI = "${ICSS_EMAC_LLD_GIT_URI};destsuffix=${ICSS_EMAC_LLD_GIT_DESTSUFFIX};protocol=${ICSS_EMAC_LLD_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +SRCREV = "${ICSS_EMAC_LLD_SRCREV}"
> +PV = "01.00.00.07C"
> +INC_PR = "r0"
> +
> +S = "${WORKDIR}/${ICSS_EMAC_LLD_GIT_DESTSUFFIX}"
> diff --git a/recipes-bsp/icss-emac-lld/icss-emac-lld_git.bb b/recipes-bsp/icss-emac-lld/icss-emac-lld_git.bb
> new file mode 100644
> index 0000000..272529b
> --- /dev/null
> +++ b/recipes-bsp/icss-emac-lld/icss-emac-lld_git.bb
> @@ -0,0 +1,26 @@
> +DESCRIPTION = "TI ICSS-EMAC low level driver library"
> +
> +DEPENDS="common-csl-ip pruss-lld osal"
> +
> +include icss-emac-lld.inc
> +
> +PR = "${INC_PR}.0"
> +
> +COMPATIBLE_MACHINE = "am57xx-evm|ti33x|ti43x"
> +
> +TARGET_NAME_am57xx-evm = "SOC_AM572x"
> +TARGET_NAME_ti33x = "SOC_AM335x"
> +TARGET_NAME_ti43x = "SOC_AM437x"
> +
> +EXTRA_OEMAKE += "-f makefile_armv7 PDK_INSTALL_PATH=${STAGING_INCDIR} TARGET=${TARGET_NAME}"
> +
> +do_compile () {
> +#   Build the lib
> +    oe_runmake clean
> +    oe_runmake lib
> +}
> +
> +do_install () {
> +#   Install the lib
> +    oe_runmake install INSTALL_INC_BASE_DIR=${D}${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir}
> +}
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti