[meta-ti] [PATCH] stw-lld-rtos: Added rtos recipe for stw-lld

[Mahesh Radhakrishnan]

Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2 at ti.com>
---
 recipes-bsp/stw-lld/stw-lld-rtos_git.bb | 60 +++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 recipes-bsp/stw-lld/stw-lld-rtos_git.bb

diff --git a/recipes-bsp/stw-lld/stw-lld-rtos_git.bb b/recipes-bsp/stw-lld/stw-lld-rtos_git.bb
new file mode 100644
index 0000000..e50fd45
--- /dev/null
+++ b/recipes-bsp/stw-lld/stw-lld-rtos_git.bb
@@ -0,0 +1,60 @@
+require recipes-ti/includes/ti-paths.inc
+require recipes-ti/includes/ti-staging.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM_dra7xx-evm = "file://stw_lld_component.mk;beginline=1;endline=35;md5=2a19315729a9cb8a4a463e920f36e090"
+
+COMPATIBLE_MACHINE = "dra7xx-evm"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = " common-csl-ip-rtos \
+            pm-lld-rtos \
+            vps-lld-rtos \
+"
+
+STW_LLD_GIT_URI = "git://gerrit01.dal.design.ti.com:8445/ADAS/stw_lld"
+STW_LLD_GIT_PROTOCOL = "https"
+STW_LLD_GIT_BRANCH = "master"
+STW_LLD_GIT_DESTSUFFIX = "git/ti/drv/stw_lld"
+
+# Below commit ID corresponds to "REL.PDK.TDA.01.07.00.06"
+STW_LLD_SRCREV = "63391ee1bf978eef61ea472ec4fcec7b77de7d0c"
+
+BRANCH = "${STW_LLD_GIT_BRANCH}"
+SRC_URI = "${STW_LLD_GIT_URI};destsuffix=${STW_LLD_GIT_DESTSUFFIX};protocol=${STW_LLD_GIT_PROTOCOL};branch=${BRANCH}"
+
+SRCREV = "${STW_LLD_SRCREV}"
+PV = "01.00.00.00"
+PR = "r0"
+
+S = "${WORKDIR}/${STW_LLD_GIT_DESTSUFFIX}"
+
+export TOOLCHAIN_PATH_A15 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export FPULIB_PATH = "${GCC_ARM_NONE_TOOLCHAIN}/lib/gcc/arm-none-eabi/4.9.3/fpu/"
+export TOOLCHAIN_PATH_M4 = "${M4_TOOLCHAIN_INSTALL_DIR}"
+export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+
+export PDK_STW_LLD_ROOT_PATH = "${WORKDIR}/git"
+
+# Used by DEST_ROOT to redirect binary and obj files away from sysroot PDK tree
+OBJ_DIR = "${WORKDIR}/git/ti/binary"
+
+LIMSOCS_dra7xx-evm="dra72x dra75x dra78x"
+LIMBOARDS_dra7xx-evm="evmDRA72x evmDRA75x evmDRA78x"
+
+do_compile() {
+
+    make clean all LIMIT_SOCS="${LIMSOCS}" LIMIT_BOARDS="${LIMBOARDS}" DEST_ROOT=${OBJ_DIR}
+
+    tar -cf stw_lld.tar --exclude='*.tar' --exclude='*.git*' ./*
+}
+
+do_install() {
+
+    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/stw_lld
+    find -name "*.tar" -exec tar xf {} -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/stw_lld \;
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
+
-- 
1.9.1