[meta-ti] [PATCH] ti-pdk-setup: Add ti-pdk-setup recipe

[Jacob Stiffler]

On 7/6/2017 6:37 PM, Mahesh Radhakrishnan wrote:
> Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2 at ti.com>
> ---
>   recipes-ti/ti-pdk-setup/ti-pdk-setup_git.bb | 104 ++++++++++++++++++++++++++++
>   1 file changed, 104 insertions(+)
>   create mode 100644 recipes-ti/ti-pdk-setup/ti-pdk-setup_git.bb
>
> diff --git a/recipes-ti/ti-pdk-setup/ti-pdk-setup_git.bb b/recipes-ti/ti-pdk-setup/ti-pdk-setup_git.bb
> new file mode 100644
> index 0000000..bd66f56
> --- /dev/null
> +++ b/recipes-ti/ti-pdk-setup/ti-pdk-setup_git.bb
> @@ -0,0 +1,104 @@
> +DESCRIPTION = "Package containing scripts to setup the PDK development environment"
> +LICENSE = "BSD"
> +LIC_FILES_CHKSUM = "file://release/full/pdksetupenv.sh;beginline=1;endline=20;md5=1858f90ca160daa7ca1b05dc3e474791"
> +
> +require recipes-ti/includes/ti-paths-append.inc
> +
> +PDK_SETUP_GIT_URI = "git://git@bitbucket.itg.ti.com/processor-sdk/processor-pdk-packages.git"
> +PDK_SETUP_GIT_PROTOCOL = "ssh"
> +PDK_SETUP_GIT_BRANCH = "master"
> +
> +# Below commit ID corresponds to "DEV.PDK_PACKAGES.01.00.00.01"
> +PDK_SETUP_SRCREV = "23f310087fded4955d6d64e6df20fd057d1cede8"
> +
> +BRANCH = "${PDK_SETUP_GIT_BRANCH}"
> +SRC_URI = "${PDK_SETUP_GIT_URI};protocol=${PDK_SETUP_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +SRCREV = "${PDK_SETUP_SRCREV}"
> +PV = "01.00.00.01"
> +PR = "r0"
> +
> +S = "${WORKDIR}/git/"
> +
> +CLEANBROKEN = "1"
> +
> +LIMIT_SOCS_ti33x = "am335x"
> +LIMIT_SOCS_ti43x = "am437x"
> +LIMIT_SOCS_omap-a15 = "am571x am572x"
> +LIMIT_SOCS_dra7xx-evm = "dra72x dra75x dra78x"
> +LIMIT_SOCS_omapl137-evm = "omapl137"
> +LIMIT_SOCS_omapl138-lcdk = "omapl138"
> +LIMIT_SOCS_k2hk-evm = "k2h k2k"
> +LIMIT_SOCS_k2e-evm = "k2e"
> +LIMIT_SOCS_k2l-evm = "k2l"
> +LIMIT_SOCS_k2g = "k2g"
> +LIMIT_SOCS_c665x-evm = "c665x"
> +LIMIT_SOCS_c667x-evm = "c6678"
> +
> +LIMIT_BOARDS_ti33x = "evmAM335x icev2AM335x bbbAM335x skAM335x"
> +LIMIT_BOARDS_ti43x = "evmAM437x idkAM437x skAM437x"
> +LIMIT_BOARDS_omap-a15 = "evmAM572x idkAM571x idkAM572x"
> +LIMIT_BOARDS_dra7xx-evm = "evmDRA72x evmDRA75x evmDRA78x"
> +LIMIT_BOARDS_omapl137-evm = "evmOMAPL137"
> +LIMIT_BOARDS_omapl138-lcdk = "lcdkOMAPL138"
> +LIMIT_BOARDS_k2hk-evm = "evmK2H evmK2K"
> +LIMIT_BOARDS_k2e-evm = "evmK2E"
> +LIMIT_BOARDS_k2l-evm = "evmK2L"
> +LIMIT_BOARDS_k2g = "evmK2G iceK2G"
> +LIMIT_BOARDS_c665x-evm = "evmC6657"
> +LIMIT_BOARDS_c667x-evm = "evmC6678"

LIMIT_BOARDS and LIMIT_SOCS should not need to be set here. They can be 
obtained from the machine configuration as TI_PDK_LIMIT_SOCS and 
TI_PDK_LIMIT_BOARDS.

> +
> +PDK_SOC = "${@'${MACHINE}'.replace('-evm','')}"
> +PDK_SOC_omapl138-lcdk = "${@'${MACHINE}'.replace('-lcdk','')}"
> +
> +do_compile() {
> +    :
> +}
> +
> +do_install() {
> +    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +
> +    install -m 0755 release/full/pdksetupenv.sh ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    install -m 0755 release/full/pdksetupenv.bat ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    install -m 0755 release/full/pdkProjectCreate.bat ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    install -m 0755 release/full/pdkProjectCreate.sh ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    install -m 0755 release/full/pdkAppImageCreate.bat ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    install -m 0755 release/full/pdkAppImageCreate.sh ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    install -m 0755 release/full/macros.ini ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +    install -m 0644 release/full/Rules.make ${D}${PDK_INSTALL_DIR_RECIPE}/packages
> +
> +    sed -i -e "s|__PDK_VER__|${PDK_VERSION}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdkProjectCreate.sh
> +    sed -i -e "s|__PDK_VER__|${PDK_VERSION}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdkProjectCreate.bat
> +
> +    sed -i -e "s|__LIMIT_SOCS__|${LIMIT_SOCS}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdksetupenv.sh
> +    sed -i -e "s|__LIMIT_SOCS__|${LIMIT_SOCS}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdksetupenv.bat
> +    sed -i -e "s|__LIMIT_SOCS__|${LIMIT_SOCS}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/Rules.make
> +
> +    sed -i -e "s|__LIMIT_BOARDS__|${LIMIT_BOARDS}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdksetupenv.sh
> +    sed -i -e "s|__LIMIT_BOARDS__|${LIMIT_BOARDS}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdksetupenv.bat
> +    sed -i -e "s|__LIMIT_BOARDS__|${LIMIT_BOARDS}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/Rules.make
> +
> +    TI_PDK_VERSION=`echo ${PDK_VERSION} | sed -e 's|\.|_|g' -e 's|^0||'`
> +
> +    sed -i -e "s|__PDK_SOC__|${PDK_SOC}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/Rules.make
> +    sed -i -e "s|__PDK_VER__|${TI_PDK_VERSION}|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/Rules.make
> +}
> +
> +do_install_append_omapl1() {
> +    sed -i -e "s|c66x|c674x|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdksetupenv.sh
> +    sed -i -e "s|c66x|c674x|g" \
> +        ${D}${PDK_INSTALL_DIR_RECIPE}/packages/pdksetupenv.bat
> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages/*"