[meta-ti] [PATCH v2 25/37] pm-lld-rtos: Adding rtos recipe for pm-lld

[Mahesh Radhakrishnan]

Upstreaming TI RTOS low level driver for Power Management module (PM)
Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2 at ti.com>
---

v2 - Added summary & merged in to a single recipe

 recipes-bsp/pm-lld/pm-lld-rtos_git.bb | 95 +++++++++++++++++++++++++++++++++++
 1 file changed, 95 insertions(+)
 create mode 100644 recipes-bsp/pm-lld/pm-lld-rtos_git.bb

diff --git a/recipes-bsp/pm-lld/pm-lld-rtos_git.bb b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
new file mode 100644
index 0000000..c976deb
--- /dev/null
+++ b/recipes-bsp/pm-lld/pm-lld-rtos_git.bb
@@ -0,0 +1,95 @@
+SUMMARY = "TI RTOS driver for Power Management module (PM)"
+
+require recipes-ti/includes/ti-paths.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://Power.h;beginline=1;endline=31;md5=527b91fdcd26cd19ac07a754f45dedbe"
+
+COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|k2g"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+
+PM_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/pm-lld.git"
+PM_LLD_GIT_PROTOCOL = "git"
+PM_LLD_GIT_BRANCH = "int_pm_am335x"
+PM_LLD_GIT_BRANCH_dra7xx-evm = "master"
+PM_LLD_GIT_DESTSUFFIX = "git/ti/drv/pm"
+
+# Below commit ID corresponds to "DEV.PM_LLD.01.04.00.01"
+PM_LLD_SRCREV = "c4908f94b3e655e6298aa9bfe9bbffbbc5d16111"
+
+# Below commit ID corresponds to "REL.PDK.TDA.01.07.00.06"
+PM_LLD_SRCREV_dra7xx-evm = "46ea13503d2991f636197edb206a9f62cea398d4"
+
+BRANCH = "${PM_LLD_GIT_BRANCH}"
+SRC_URI = "${PM_LLD_GIT_URI};destsuffix=${PM_LLD_GIT_DESTSUFFIX};protocol=${PM_LLD_GIT_PROTOCOL};branch=${BRANCH}"
+
+#PATCHTOOL = "git"
+#SRC_URI_append = " \
+#    file://.patch \
+#"
+
+SRCREV = "${PM_LLD_SRCREV}"
+PV = "01.04.00.01"
+PR = "r0"
+
+S = "${WORKDIR}/${PM_LLD_GIT_DESTSUFFIX}"
+
+DEPENDS = " ti-sysbios \
+            gcc-arm-none-eabi-native \
+            osal-rtos \
+            ca-certificates-native \
+            ti-pdk-setup \
+"
+DEPENDS_append_omap-a15 = " ti-cgt-arm-native \
+                            ti-cgt6x-native \
+                            common-csl-ip-rtos \
+"
+DEPENDS_append_ti33x = " starterware-rtos \
+"
+DEPENDS_append_ti43x = " starterware-rtos \
+"
+DEPENDS_append_k2g = " common-csl-ip-rtos \
+                       ti-cgt6x-native \
+"
+
+# Fetch task cannot be completed until after ca-certificates-native populates sysroot with the SSL certificates
+do_fetch[depends] = "ca-certificates-native:do_populate_sysroot"
+
+export TOOLCHAIN_PATH_A15 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export TOOLCHAIN_PATH_A8 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export TOOLCHAIN_PATH_A9 = "${GCC_ARM_NONE_TOOLCHAIN}"
+export FPULIB_PATH = "${GCC_ARM_NONE_TOOLCHAIN}/lib/gcc/arm-none-eabi/4.9.3/fpu/"
+export TOOLCHAIN_PATH_M4 = "${M4_TOOLCHAIN_INSTALL_DIR}"
+export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
+export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
+export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
+
+export PDK_PM_ROOT_PATH = "${WORKDIR}/git"
+
+# Used by DEST_ROOT to redirect binary and obj files away from sysroot PDK tree
+OBJ_DIR = "${WORKDIR}/git/ti/binary"
+
+do_compile() {
+    make clean lib xdc_meta doxygen LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}" DEST_ROOT=${OBJ_DIR}
+
+    # Remove unnecessary files from packaging
+    rm -rf patches/
+
+    # Cleanup docs
+    rm -rf docs/ReleaseNotes_PM_LLD.doc
+    rm -rf internal/
+
+    #archive
+    tar -cf pm_lld.tar --exclude='*.tar' ./*
+}
+
+do_install() {
+    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm
+    find -name "*.tar" -exec tar xf {} --no-same-owner -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/drv/pm \;
+}
+
+FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
+
+INSANE_SKIP_${PN} = "arch staticdev"
-- 
1.9.1