[meta-ti] [thud][PATCH] vxd-dec-fw: Add the recipe for vxd-dec-fw

[Denys Dmytriyenko]

Thanks. Overall patches look fine. May I suggest putting all 3 of the recipes 
into a single directory? Say, recipes-bsp/ti-img-encode-decode/ with FW, 
kernel module and test app recipes in there. There are many other cases of 
such placement in meta-ti, especially LLDs. Also, can extract common pieces 
(like SRC_URI) into a shared .inc file, if needed.

Denys


On Thu, Jun 20, 2019 at 05:32:57PM -0500, Angela Stegmaier wrote:
> Add the firmware packaging recipe for the video decoder
> for J721E devices.
> 
> Signed-off-by: Angela Stegmaier <angelabaker at ti.com>
> ---
>  recipes-bsp/vxd-dec-fw/vxd-dec-fw_git.bb | 35 ++++++++++++++++++++++++++++++++
>  1 file changed, 35 insertions(+)
>  create mode 100644 recipes-bsp/vxd-dec-fw/vxd-dec-fw_git.bb
> 
> diff --git a/recipes-bsp/vxd-dec-fw/vxd-dec-fw_git.bb b/recipes-bsp/vxd-dec-fw/vxd-dec-fw_git.bb
> new file mode 100644
> index 0000000..e8a1f72
> --- /dev/null
> +++ b/recipes-bsp/vxd-dec-fw/vxd-dec-fw_git.bb
> @@ -0,0 +1,35 @@
> +SUMMARY = "Video Decoding Firmware Packaging recipe"
> +LICENSE = "TI-TFL"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=84ca7278930db001870686ad997d6bb1"
> +
> +PROTOCOL = "git"

Where's this variable used?


> +BRANCH = "master"
> +SRCREV = "0acbf1d0a7c7eaca0ef14c1a30ce313ea82147e5"
> +
> +SRC_URI = "git://git.ti.com/jacinto7_multimedia/ti-img-encode-decode.git;protocol=git;branch=${BRANCH}"
> +
> +S = "${WORKDIR}/git"
> +
> +PV = "1.0-git${SRCPV}"
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +VXD_FW_DIR = "${S}/decoder/firmware/"
> +
> +# make sure that lib/firmware, and all its contents are part of the package
> +FILES_${PN} += "${base_libdir}/firmware"
> +
> +do_install() {
> +  install -d ${D}${base_libdir}/firmware
> +  install -m 0755 ${VXD_FW_DIR}/pvdec_full_bin.fw ${D}${base_libdir}/firmware
> +}
> +
> +# This is used to prevent the build system to strip the executables
> +INHIBIT_PACKAGE_STRIP = "1"
> +# This is used to prevent the build system to split the debug info in a separate file
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> +# As it likely to be a different arch from the Yocto build, disable checking by adding "arch" to INSANE_SKIP
> +INSANE_SKIP_${PN} += "arch"
> +
> +# we don't want to configure and build the source code
> +do_compile[noexec] = "1"
> +do_configure[noexec] = "1"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti