[meta-virtualization] [PATCH 1/2] protobuf: update 2.5.0 -> 3.0.2

[Venkateswara Rao Mandela]

- Create a separate file for 3.0.2 protobuf. This is the latest version
as on Sep 8 2016.

Mimic the recipe organization used by m4 (oe-core/meta/recipes-devtools/m4)

- Move the description,source URI and license checksum to protobuf.inc
- Move tar ball checksum into protobuf-3.0.2.inc
- Create a separate recipes for native and cross compilation

Signed-off-by: Venkateswara Rao Mandela <venkat.mandela at ti.com>
---
 recipes-devtools/protobuf/protobuf-3.0.2.inc       |  4 ++
 recipes-devtools/protobuf/protobuf-native_3.0.2.bb |  5 ++
 recipes-devtools/protobuf/protobuf.inc             | 14 ++++
 recipes-devtools/protobuf/protobuf_3.0.2.bb        | 82 ++++++++++++++++++++++
 4 files changed, 105 insertions(+)
 create mode 100644 recipes-devtools/protobuf/protobuf-3.0.2.inc
 create mode 100644 recipes-devtools/protobuf/protobuf-native_3.0.2.bb
 create mode 100644 recipes-devtools/protobuf/protobuf.inc
 create mode 100644 recipes-devtools/protobuf/protobuf_3.0.2.bb

diff --git a/recipes-devtools/protobuf/protobuf-3.0.2.inc b/recipes-devtools/protobuf/protobuf-3.0.2.inc
new file mode 100644
index 0000000..d64b1ff
--- /dev/null
+++ b/recipes-devtools/protobuf/protobuf-3.0.2.inc
@@ -0,0 +1,4 @@
+require protobuf.inc
+
+SRC_URI[md5sum] = "845b39e4b7681a2ddfd8c7f528299fbb"
+SRC_URI[sha256sum] = "b700647e11556b643ccddffd1f41d8cb7704ed02090af54cc517d44d912d11c1"
diff --git a/recipes-devtools/protobuf/protobuf-native_3.0.2.bb b/recipes-devtools/protobuf/protobuf-native_3.0.2.bb
new file mode 100644
index 0000000..1104d94
--- /dev/null
+++ b/recipes-devtools/protobuf/protobuf-native_3.0.2.bb
@@ -0,0 +1,5 @@
+require protobuf-${PV}.inc
+
+EXTRA_OECONF += " --with-protoc=echo --disable-shared"
+
+inherit native autotools
diff --git a/recipes-devtools/protobuf/protobuf.inc b/recipes-devtools/protobuf/protobuf.inc
new file mode 100644
index 0000000..2778037
--- /dev/null
+++ b/recipes-devtools/protobuf/protobuf.inc
@@ -0,0 +1,14 @@
+SUMMARY = "protobuf"
+DESCRIPTION = "Protocol Buffers are a way of encoding structured data in \
+an efficient yet extensible format. Google uses Protocol Buffers for \
+almost all of its internal RPC protocols and file formats."
+HOMEPAGE = "https://github.com/google/protobuf/"
+SECTION = "console/tools"
+LICENSE = "BSD-3-Clause"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=35953c752efc9299b184f91bef540095"
+
+inherit autotools
+
+SRC_URI = "https://github.com/google/protobuf/archive/v${PV}.tar.gz \
+        "
diff --git a/recipes-devtools/protobuf/protobuf_3.0.2.bb b/recipes-devtools/protobuf/protobuf_3.0.2.bb
new file mode 100644
index 0000000..779ce6e
--- /dev/null
+++ b/recipes-devtools/protobuf/protobuf_3.0.2.bb
@@ -0,0 +1,82 @@
+require protobuf-${PV}.inc
+
+EXCLUDE_FROM_WORLD = "1"
+
+SRC_URI += "file://protobuf-allow-running-python-scripts-from-anywhere.patch \
+        file://run-ptest"
+
+EXTRA_OECONF += " --with-protoc=${STAGING_BINDIR_NATIVE}/protoc"
+inherit autotools setuptools ptest
+
+DEPENDS += "protobuf-native"
+RDEPENDS_${PN}-ptest = "bash python"
+
+PYTHON_SRC_DIR="python"
+TEST_SRC_DIR="examples"
+LANG_SUPPORT="python"
+
+do_compile() {
+        # Compile protoc compiler
+        base_do_compile
+}
+
+do_compile_ptest() {
+        # Modify makefile to use the cross-compiler
+        sed -e "s|c++|${CXX}|g" -i "${S}/${TEST_SRC_DIR}/Makefile"
+
+        mkdir -p "${B}/${TEST_SRC_DIR}"
+
+        # Add the location of the cross-compiled header and library files
+        # which haven't been installed yet.
+        cp "${B}/protobuf.pc" "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        sed -e 's|libdir=|libdir=${PKG_CONFIG_SYSROOT_DIR}|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        sed -e 's|Cflags:|Cflags: -I${S}/src|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        sed -e 's|Libs:|Libs: -L${B}/src/.libs|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
+        export PKG_CONFIG_PATH="${B}/${TEST_SRC_DIR}"
+
+        # Save the pkgcfg sysroot variable, and update it to nothing so
+        # that it doesn't append the sysroot to the beginning of paths.
+        # The header and library files aren't installed to the target
+        # system yet.  So the absolute paths were specified above.
+        save_pkg_config_sysroot_dir=$PKG_CONFIG_SYSROOT_DIR
+        export PKG_CONFIG_SYSROOT_DIR=
+
+        # Compile the tests
+        for lang in ${LANG_SUPPORT}; do
+                oe_runmake -C "${S}/${TEST_SRC_DIR}" ${lang}
+        done
+
+        # Restore the pkgconfig sysroot variable
+        export PKG_CONFIG_SYSROOT_DIR=$save_pkg_config_sysroot_dir
+}
+
+do_install() {
+        local olddir=`pwd`
+
+        # Install protoc compiler
+        autotools_do_install
+
+        # Install header files
+        export PROTOC="${STAGING_BINDIR_NATIVE}/protoc"
+        cd "${S}/${PYTHON_SRC_DIR}"
+        distutils_do_install
+
+        cd "$olddir"
+}
+
+do_install_ptest() {
+        local olddir=`pwd`
+
+        cd "${S}/${TEST_SRC_DIR}"
+        install -d "${D}/${PTEST_PATH}"
+        for i in add_person* list_people*; do
+                if [ -x "$i" ]; then
+                        install "$i" "${D}/${PTEST_PATH}"
+                fi
+        done
+        cp "${S}/${TEST_SRC_DIR}/addressbook_pb2.py" "${D}/${PTEST_PATH}"
+
+        cd "$olddir"
+}
+
+BBCLASSEXTEND = "nativesdk"
-- 
2.9.3