[meta-xilinx] [RFC 1/2] recipes-bsp/fsbl-platform-headers: Add recipe for ps7_init_gpl.[ch]

[Nathan Rossi]

* This recipe provides the ps7_init_gpl.[ch] files in order to build a
  functional fsbl or u-boot-spl image
* The files are populated in the sysroot under
  /usr/src/zynq7-platform
* Paths for the sysroot files are defined in
  zynq7-platform-headers.bbclass

Signed-off-by: Nathan Rossi <nathan.rossi at xilinx.com>
---
 classes/zynq7-platform-headers.bbclass             |  4 ++
 .../fsbl-platform-headers_2014.3.bb                | 51 ++++++++++++++++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 classes/zynq7-platform-headers.bbclass
 create mode 100644 recipes-bsp/platform-headers/fsbl-platform-headers_2014.3.bb

diff --git a/classes/zynq7-platform-headers.bbclass b/classes/zynq7-platform-headers.bbclass
new file mode 100644
index 0000000..c0c9a22
--- /dev/null
+++ b/classes/zynq7-platform-headers.bbclass
@@ -0,0 +1,4 @@
+# Define the path to the zynq platform headers
+PLATFORM_HEADERS_DIR = "/usr/src/zynq7-platform"
+PLATFORM_HEADERS_STAGE_DIR = "${STAGING_DIR_HOST}${PLATFORM_HEADERS_DIR}"
+
diff --git a/recipes-bsp/platform-headers/fsbl-platform-headers_2014.3.bb b/recipes-bsp/platform-headers/fsbl-platform-headers_2014.3.bb
new file mode 100644
index 0000000..98cc36a
--- /dev/null
+++ b/recipes-bsp/platform-headers/fsbl-platform-headers_2014.3.bb
@@ -0,0 +1,51 @@
+SUMMARY = "Xilinx FSBL Platform Headers"
+DESCRPTION = "Xilinx FSBL ps7_init_gpl.c/h platform headers, used for building u-boot-spl and fsbl"
+HOMEPAGE = "http://www.xilinx.com"
+SECTION = "bsp"
+
+inherit zynq7-platform-headers
+
+PROVIDES += "virtual/zynq7-platform-headers"
+
+LIC_FILES_CHKSUM = "files://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+
+# This license refers to only the ps7_init_gpl.c and ps7_init_gpl.h, all other
+# files in the repo have a different license, refer to the source for more
+# detail.
+LICENSE = "GPLv2+"
+
+SRC_URI = "git://github.com/Xilinx/embeddedsw.git;protocol=https;branch=master"
+SRCREV = "13f49eb056530972797aa3d7eb3f70c0ab43e925"
+
+S = "${WORKDIR}/git"
+
+INHIBIT_DEFAULT_DEPS = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+BOARD_NAME_zc702-zynq7 = "zc702"
+BOARD_NAME_zc706-zynq7 = "zc706"
+BOARD_NAME_zedboard-zynq7 = "zed"
+
+FSBL_MISC_PATH = "lib/sw_apps/zynq_fsbl/misc/${BOARD_NAME}"
+
+COMPATIBLE_MACHINE = "zc702-zynq7|zc706-zynq7|zedboard-zynq7"
+
+do_compile() {
+	:
+}
+
+do_install() {
+	install -d ${D}${PLATFORM_HEADERS_DIR}
+	install -m 0644 ${S}/${FSBL_MISC_PATH}/ps7_init_gpl.c ${D}${PLATFORM_HEADERS_DIR}/
+	install -m 0644 ${S}/${FSBL_MISC_PATH}/ps7_init_gpl.h ${D}${PLATFORM_HEADERS_DIR}/
+}
+
+python sysroot_stage_all () {
+    oe.path.copytree(d.expand("${D}${PLATFORM_HEADERS_DIR}"), d.expand("${SYSROOT_DESTDIR}${PLATFORM_HEADERS_DIR}"))
+}
+
+FILES_${PN} += " \
+		${PLATFORM_HEADERS_DIR}/ps7_init_gpl.c \
+		${PLATFORM_HEADERS_DIR}/ps7_init_gpl.h \
+		"
+
-- 
2.1.1