[meta-xilinx] [PATCH V3 1/3] qemu: Build Xilinx's QEMU

[Alistair Francis]

Build Xilinx's QEMU in the qemu-xilinx direcotry.

Signed-off-by: Alistair Francis <alistair.francis at xilinx.com>
---
 recipes-devtools/qemu/qemu-xilinx_2.2.5.bb | 55 ++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 recipes-devtools/qemu/qemu-xilinx_2.2.5.bb

diff --git a/recipes-devtools/qemu/qemu-xilinx_2.2.5.bb b/recipes-devtools/qemu/qemu-xilinx_2.2.5.bb
new file mode 100644
index 0000000..10c5ff8
--- /dev/null
+++ b/recipes-devtools/qemu/qemu-xilinx_2.2.5.bb
@@ -0,0 +1,55 @@
+QEMU_TARGETS ?= "aarch64 arm microblaze microblazeel"
+
+require recipes-devtools/qemu/qemu.inc
+
+SUMMARY = "Xilinx's fork of a fast open source processor emulator"
+HOMEPAGE = "https://github.com/xilinx/qemu/"
+
+LIC_FILES_CHKSUM = " \
+		file://COPYING;md5=441c28d2cf86e15a37fa47e15a72fbac \
+		file://COPYING.LIB;endline=24;md5=c04def7ae38850e7d3ef548588159913 \
+		"
+
+SRCREV = "8e51bc12d87dd76cc5fd0a112228f3c007c7629f"
+SRC_URI = "git://github.com/Xilinx/qemu.git;protocol=https;nobranch=1  \
+		"
+
+S = "${WORKDIR}/git"
+
+PV = "2.2.50+git+${SRCPV}"
+
+# Disable KVM completely
+KVMENABLE = "--disable-kvm"
+
+# Strip all appends (needed because qemu.inc adds patches using overrides)
+SRC_URI[_append] = ""
+
+DISABLE_STATIC_pn-qemu-xilinx-native = ""
+
+PACKAGECONFIG[quorum] = "--enable-quorum, --disable-quorum, gnutls,"
+PACKAGECONFIG[vnc-tls] = "--enable-vnc --enable-vnc-tls,--disable-vnc-tls, gnutls,"
+PACKAGECONFIG[vnc-ws] = "--enable-vnc --enable-vnc-ws,--disable-vnc-ws, gnutls,"
+PACKAGECONFIG[gcrypt] = "--enable-libgcrypt,--disable-libgcrypt,libgcrypt,"
+PACKAGECONFIG[nss] = ""
+PACKAGECONFIG[nettle] = ""
+PACKAGECONFIG[glx] = ""
+PACKAGECONFIG[gnutls] = ""
+PACKAGECONFIG[bzip2] = ""
+
+# append a suffix dir, to allow multiple versions of QEMU to be installed
+datadir_append = "/qemu-xilinx"
+bindir_append = "/qemu-xilinx"
+libexecdir_append = "/qemu-xilinx"
+
+# ensure configure is passed the modified dirs
+EXTRA_OECONF += " \
+		--bindir=${bindir} \
+		--datadir=${datadir} \
+		--mandir=${mandir} \
+		--docdir=${docdir} \
+		"
+
+do_install() {
+	export STRIP="true"
+	autotools_do_install
+}
-- 
2.7.4