[meta-xilinx] [PATCH V5 2/3] qemu-devicetrees: Build the Xilinx QEMU device trees

[Alistair Francis]

Signed-off-by: Alistair Francis <alistair.francis at xilinx.com>
---
 recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb | 33 +++++++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb

diff --git a/recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb b/recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb
new file mode 100644
index 0000000..b4c914b
--- /dev/null
+++ b/recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Xilinx's hardware device trees required for QEMU"
+HOMEPAGE = "https://github.com/xilinx/qemu-devicetrees/"
+LICENSE = "BSD"
+DEPENDS += "dtc-native"
+
+inherit deploy
+
+LIC_FILES_CHKSUM = "file://Makefile;beginline=1;endline=27;md5=7348b6cbcae69912cb1dee68d6c68d99"
+
+SRCREV = "46faf58cd14cdfd06cae7c076cb486af8565ab6a"
+SRC_URI = "git://github.com/Xilinx/qemu-devicetrees.git;protocol=https;nobranch=1"
+
+S = "${WORKDIR}/git"
+
+# Don't need to do anything
+do_install() {
+	:
+}
+
+do_deploy() {
+	for DTS_FILE in ${S}/LATEST/SINGLE_ARCH/*.dtb; do
+		if [ ! -f ${DTS_FILE} ]; then
+			bbwarn "${DTS_FILE} is not available!"
+			continue
+		fi
+		DTS_NAME=`basename -s .dtb ${DTS_FILE}`
+		install -d ${DEPLOYDIR}
+		install -d ${DEPLOYDIR}/qemu-hw-devicetrees
+		install -m 0644 ${S}/LATEST/SINGLE_ARCH/${DTS_NAME}.dtb ${DEPLOYDIR}/qemu-hw-devicetrees/${DTS_NAME}.dtb
+	done
+}
+
+addtask deploy after do_install
-- 
2.7.4