[meta-xilinx] [PATCH V4 2/3] qemu-devicetrees: Build the Xilinx QEMU device trees

[Nathan Rossi]

On Wed, Sep 28, 2016 at 5:58 AM, Alistair Francis
<alistair.francis at xilinx.com> wrote:
> Signed-off-by: Alistair Francis <alistair.francis at xilinx.com>
> ---
>  recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb | 31 +++++++++++++++++++++++++
>  1 file changed, 31 insertions(+)
>  create mode 100644 recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb
>
> diff --git a/recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb b/recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb
> new file mode 100644
> index 0000000..4a04e4c
> --- /dev/null
> +++ b/recipes-devtools/qemu/qemu-devicetrees_2.2.5.bb
> @@ -0,0 +1,31 @@
> +SUMMARY = "Xilinx's hardware device trees required for QEMU"
> +HOMEPAGE = "https://github.com/xilinx/qemu-devicetrees/"
> +LICENSE = "BSD"
> +DEPENDS += "dtc-native"
> +
> +LIC_FILES_CHKSUM = "file://Makefile;beginline=1;endline=27;md5=7348b6cbcae69912cb1dee68d6c68d99"
> +
> +SRCREV = "46faf58cd14cdfd06cae7c076cb486af8565ab6a"
> +SRC_URI = "git://github.com/Xilinx/qemu-devicetrees.git;protocol=https;nobranch=1"
> +
> +S = "${WORKDIR}/git"
> +
> +# Don't need to do anything
> +do_install() {
> +       :
> +}
> +
> +do_deploy() {
> +       for DTS_FILE in ${S}/LATEST/SINGLE_ARCH/*.dtb; do
> +               if [ ! -f ${DTS_FILE} ]; then
> +                       bbwarn "${DTS_FILE} is not available!"
> +                       continue
> +               fi
> +               DTS_NAME=`basename -s .dtb ${DTS_FILE}`
> +               install -d ${DEPLOY_DIR_IMAGE}
> +               install -d ${DEPLOY_DIR_IMAGE}/qemu-hw-devicetrees
> +               install -m 0644 ${S}/LATEST/SINGLE_ARCH/${DTS_NAME}.dtb ${DEPLOY_DIR_IMAGE}/qemu-hw-devicetrees/${DTS_NAME}.dtb

Sorry for missing this in the previous comments but I had only come
across the issue recently. It turns out deploying directly to
DEPLOY_DIR_IMAGE skips the sstate cache and causes some problems (the
deployed objects don't always get deployed) when deleting the tmp
directory and rebuilding the output from sstate-cache.

In the patch series I have just sent out I fixed this behaviour for
device-tree.bb and some other recipes. Here is the change, essentially
inherit deploy in the recipe and use the "DEPLOYDIR" variable instead
of DEPLOY_DIR_IMAGE. This is the patch for device-tree that covers the
change:

https://github.com/nathanrossi/meta-xilinx/commit/c52a435a45eae4e13e1c6a5a43039e84f0d3bbba

But otherwise this patch is good to be merged.

Thanks,
Nathan

> +       done
> +}
> +
> +addtask deploy after do_install
> --
> 2.7.4
>