[meta-xilinx] [PATCH v2 1/2] zynqmp-pmu-config.inc: Limit to specific recipes

[Nathan Rossi]

Limit the appending/enabling of the zynqmp-pmu BBCLASSEXTEND to only
specific recipes which are used for the building of pmu-firmware. This
is just binutils, gcc, newlib, libgloss and pmu-firmware itself.

The limiting is done based on the BPN of the recipe, which is not
provided as an override so the conditional is tested with an inline
python function.

This change removes the need for the extender class to be enabled
globally which can conflict with certain recipes that were not written
to be extended by the BBCLASSEXTEND mechanism. This change also improves
the parse time avoiding the need to parse all recipes for both target
and zynqmp-pmu.

Add comment for the PACKAGE_EXTRA_ARCHS setting, so it is clear why it
is set.

Signed-off-by: Nathan Rossi <nathan at nathanrossi.com>
---
 conf/machine/include/zynqmp-pmu-config.inc | 18 ++++++++++++++++--
 1 file changed, 16 insertions(+), 2 deletions(-)

diff --git a/conf/machine/include/zynqmp-pmu-config.inc b/conf/machine/include/zynqmp-pmu-config.inc
index aa854cdcf6..ffe2cf43b4 100644
--- a/conf/machine/include/zynqmp-pmu-config.inc
+++ b/conf/machine/include/zynqmp-pmu-config.inc
@@ -1,5 +1,19 @@
 
-# Enable the use of zynqmp-pmu specific recipe builds
-BBCLASSEXTEND_append = " zynqmp-pmu"
+# Enable the use of zynqmp-pmu for specific recipes only
+def zynqmp_pmu_enable_for_bpns(d):
+    bpns = [
+        "binutils",
+        "gcc", "libgcc",
+        "newlib", "libgloss",
+        "pmu-firmware",
+        ]
+    return " zynqmp-pmu" if (d.getVar("BPN") in bpns) else ""
+
+BBCLASSEXTEND_append = "${@zynqmp_pmu_enable_for_bpns(d)}"
+
+# Add the pkgarch to the extra list, this is done to avoid warnings about
+# missing manifests due to implicit dependency chains on populate_sysroot when
+# a recipe/task depends on a IMAGE_EXTRADEPENDS/do_deploy task which is
+# provided by a zynqmp-pmu-* target.
 PACKAGE_EXTRA_ARCHS_append = " microblazeel-v9.2-bs-cmp"
 
-- 
2.14.1