[meta-xilinx] [PATCH 1/2] qemu-xilinx_2017.3.bb: Rewire QEMU recipe to adopt to Xilinx releases

[Manjukumar Matha]

Rewire so that we can update the Xilinx QEMU releases just like other
recipes

Signed-off-by: Manjukumar Matha <manjukumar.harthikote-matha at xilinx.com>
---
 recipes-devtools/qemu/qemu-xilinx.inc       | 47 +++++++++++++++++++++++++++++
 recipes-devtools/qemu/qemu-xilinx_2017.3.bb | 46 +++-------------------------
 2 files changed, 51 insertions(+), 42 deletions(-)
 create mode 100644 recipes-devtools/qemu/qemu-xilinx.inc

diff --git a/recipes-devtools/qemu/qemu-xilinx.inc b/recipes-devtools/qemu/qemu-xilinx.inc
new file mode 100644
index 0000000..9b59ecc
--- /dev/null
+++ b/recipes-devtools/qemu/qemu-xilinx.inc
@@ -0,0 +1,47 @@
+QEMU_TARGETS = "aarch64 arm microblaze microblazeel"
+
+require recipes-devtools/qemu/qemu.inc
+
+SUMMARY = "Xilinx's fork of a fast open source processor emulator"
+HOMEPAGE = "https://github.com/xilinx/qemu/"
+
+LIC_FILES_CHKSUM = " \
+		file://COPYING;md5=441c28d2cf86e15a37fa47e15a72fbac \
+		file://COPYING.LIB;endline=24;md5=c04def7ae38850e7d3ef548588159913 \
+		"
+
+PV = "${XILINX_QEMU_VERSION}-xilinx-${XILINX_RELEASE_VERSION}+git${SRCPV}"
+BRANCH ?= ""
+REPO ?= "git://github.com/Xilinx/qemu.git;protocol=https"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+S = "${WORKDIR}/git"
+
+# Disable KVM completely
+PACKAGECONFIG_remove = "kvm"
+
+# Enable libgcrypt
+PACKAGECONFIG_append = " gcrypt"
+
+DISABLE_STATIC_pn-${PN} = ""
+
+PTEST_ENABLED = ""
+
+# append a suffix dir, to allow multiple versions of QEMU to be installed
+EXTRA_OECONF_append = " \
+		--bindir=${bindir}/qemu-xilinx \
+		--libexecdir=${libexecdir}/qemu-xilinx \
+		"
+
+do_configure_prepend() {
+	# rewrite usage of 'libgcrypt-config' with 'pkg-config libgcrypt'
+	sed -r -i 's/libgcrypt-config(\s*--)/pkg-config libgcrypt\1/g' ${S}/configure
+}
+
+do_install_append() {
+	# Prevent QA warnings about installed ${localstatedir}/run
+	if [ -d ${D}${localstatedir}/run ]; then rmdir ${D}${localstatedir}/run; fi
+}
+
diff --git a/recipes-devtools/qemu/qemu-xilinx_2017.3.bb b/recipes-devtools/qemu/qemu-xilinx_2017.3.bb
index 624715d..f8a91d7 100644
--- a/recipes-devtools/qemu/qemu-xilinx_2017.3.bb
+++ b/recipes-devtools/qemu/qemu-xilinx_2017.3.bb
@@ -1,43 +1,5 @@
-QEMU_TARGETS = "aarch64 arm microblaze microblazeel"
-
-require recipes-devtools/qemu/qemu.inc
-
-SUMMARY = "Xilinx's fork of a fast open source processor emulator"
-HOMEPAGE = "https://github.com/xilinx/qemu/"
-
-LIC_FILES_CHKSUM = " \
-		file://COPYING;md5=441c28d2cf86e15a37fa47e15a72fbac \
-		file://COPYING.LIB;endline=24;md5=c04def7ae38850e7d3ef548588159913 \
-		"
-
-SRCREV = "8f8c89b18f6e4523099e41d81769fc534064b8de"
-SRC_URI = "git://github.com/Xilinx/qemu.git;protocol=https;nobranch=1"
-
-S = "${WORKDIR}/git"
-
-# Disable KVM completely
-PACKAGECONFIG_remove = "kvm"
-
-# Enable libgcrypt
-PACKAGECONFIG_append = " gcrypt"
-
-DISABLE_STATIC_pn-${PN} = ""
-
-PTEST_ENABLED = ""
-
-# append a suffix dir, to allow multiple versions of QEMU to be installed
-EXTRA_OECONF_append = " \
-		--bindir=${bindir}/qemu-xilinx \
-		--libexecdir=${libexecdir}/qemu-xilinx \
-		"
-
-do_configure_prepend() {
-	# rewrite usage of 'libgcrypt-config' with 'pkg-config libgcrypt'
-	sed -r -i 's/libgcrypt-config(\s*--)/pkg-config libgcrypt\1/g' ${S}/configure
-}
-
-do_install_append() {
-	# Prevent QA warnings about installed ${localstatedir}/run
-	if [ -d ${D}${localstatedir}/run ]; then rmdir ${D}${localstatedir}/run; fi
-}
+require qemu-xilinx.inc
 
+XILINX_RELEASE_VERSION = "v2017.3"
+XILINX_QEMU_VERSION = "v2.8.1"
+SRCREV ?= "8f8c89b18f6e4523099e41d81769fc534064b8de"
-- 
2.7.4