[meta-xilinx] [meta-xilinx-tools][PATCH] device-tree.bbappend: Add device-tree append file

[Manjukumar Matha]

Instead of replicating the device-tree recipe from meta-xilinx, append
to include the DTG way of processing and generating the dts files from
HDF

Signed-off-by: Manjukumar Matha <manjukumar.harthikote-matha at xilinx.com>
---
 .../device-tree/device-tree-generation_git.bb      | 73 ----------------------
 recipes-bsp/device-tree/device-tree.bbappend       | 44 +++++++++++++
 2 files changed, 44 insertions(+), 73 deletions(-)
 delete mode 100644 recipes-bsp/device-tree/device-tree-generation_git.bb
 create mode 100644 recipes-bsp/device-tree/device-tree.bbappend

diff --git a/recipes-bsp/device-tree/device-tree-generation_git.bb b/recipes-bsp/device-tree/device-tree-generation_git.bb
deleted file mode 100644
index 895b7b0..0000000
--- a/recipes-bsp/device-tree/device-tree-generation_git.bb
+++ /dev/null
@@ -1,73 +0,0 @@
-DESCRIPTION = "DTS generator"
-
-LICENSE = "GPLv2"
-LIC_FILES_CHKSUM = "file://xadcps/data/xadcps.mdd;md5=f7fa1bfdaf99c7182fc0d8e7fd28e04a"
-
-DEPENDS += "dtc-native"
-
-PROVIDES = "virtual/dtb"
-
-inherit xsctdt xsctyaml deploy
-
-S = "${WORKDIR}/git"
-BRANCH = "master"
-SRC_URI = "git://github.com/Xilinx/device-tree-xlnx.git;protocol=https;branch=${BRANCH}"
-#Based on xilinx-v2017.4
-SRCREV ?= "3c7407f6f802461cd5ba8545e82c64fbd177452b"
-
-PV = "xilinx+git${SRCPV}"
-
-XSCTH_BUILD_CONFIG = ""
-YAML_COMPILER_FLAGS = ""
-XSCTH_APP = "device-tree"
-
-YAML_MAIN_MEMORY_CONFIG_zcu100-zynqmp = "psu_ddr_0"
-YAML_CONSOLE_DEVICE_CONFIG_zcu100-zynqmp = "psu_uart_1"
-
-YAML_DT_BOARD_FLAGS_zcu100-zynqmp = "{BOARD zcu100-revc}"
-YAML_DT_BOARD_FLAGS_zcu102-zynqmp = "{BOARD zcu102-rev1.0}"
-YAML_DT_BOARD_FLAGS_zcu106-zynqmp = "{BOARD zcu106-reva}"
-YAML_DT_BOARD_FLAGS_zc702-zynq7 = "{BOARD zc702}"
-YAML_DT_BOARD_FLAGS_zc706-zynq7 = "{BOARD zc706}"
-YAML_DT_BOARD_FLAGS_zedboard-zynq7 = "{BOARD zedboard}"
-YAML_DT_BOARD_FLAGS_zc1254-zynqmp = "{BOARD zc1254-reva}"
-
-DEVICETREE_WORKDIR ?= "${XSCTH_WS}/${XSCTH_PROJ}"
-
-DT_PADDING_SIZE ?= "0x1000"
-
-DEVICETREE_FLAGS ?= "-R 8 -p ${DT_PADDING_SIZE} \
-		-i ${WORKDIR} \
-		-i ${DEVICETREE_WORKDIR} \
-		"
-
-DEVICETREE_PP_FLAGS ?= "-nostdinc -Ulinux \
-		-I${WORKDIR} \
-		-I${DEVICETREE_WORKDIR} \
-		${@' '.join(['-I%s' % i for i in d.getVar('KERNEL_DTS_INCLUDE', True).split()])} \
-		-x assembler-with-cpp \
-		"
-
-KERNEL_DTS_INCLUDE ??= "${STAGING_KERNEL_DIR}/include"
-
-do_compile[depends] += "virtual/kernel:do_configure"
-do_compile() {
-    # use dtc to compile
-    ${BUILD_CPP} ${DEVICETREE_PP_FLAGS} -o ${DEVICETREE_WORKDIR}/${MACHINE}-system.pp ${DEVICETREE_WORKDIR}/system-top.dts
-    dtc -I dts -O dtb ${DEVICETREE_FLAGS} -o ${DEVICETREE_WORKDIR}/${MACHINE}-system.dtb ${DEVICETREE_WORKDIR}/${MACHINE}-system.pp
-    dtc -I dtb -O dts -o ${DEVICETREE_WORKDIR}/${MACHINE}-system.dts ${DEVICETREE_WORKDIR}/${MACHINE}-system.dtb
-}
-
-do_install() {
-    install -d ${D}/boot/devicetree
-    install -m 0644 ${DEVICETREE_WORKDIR}/${MACHINE}-system.dtb ${D}/boot/devicetree/${MACHINE}-system.dtb
-}
-
-do_deploy() {
-    install -d ${DEPLOYDIR}
-    install -m 0644 ${DEVICETREE_WORKDIR}/${MACHINE}-system.dts ${DEPLOYDIR}/${MACHINE}-system.dts
-    install -m 0644 ${DEVICETREE_WORKDIR}/${MACHINE}-system.dtb ${DEPLOYDIR}/${MACHINE}-system.dtb
-}
-addtask deploy after do_install
-
-FILES_${PN} = "/boot/devicetree*"
diff --git a/recipes-bsp/device-tree/device-tree.bbappend b/recipes-bsp/device-tree/device-tree.bbappend
new file mode 100644
index 0000000..a22a79a
--- /dev/null
+++ b/recipes-bsp/device-tree/device-tree.bbappend
@@ -0,0 +1,44 @@
+DESCRIPTION = "Device Tree generation and packaging for BSP Device Trees using DTG from Xilinx"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://xadcps/data/xadcps.mdd;md5=f7fa1bfdaf99c7182fc0d8e7fd28e04a"
+
+PROVIDES = "virtual/dtb"
+
+inherit xsctdt xsctyaml
+
+S = "${WORKDIR}/git"
+BRANCH = "master"
+SRC_URI = "git://github.com/Xilinx/device-tree-xlnx.git;protocol=https;branch=${BRANCH}"
+#Based on xilinx-v2017.4
+SRCREV ?= "3c7407f6f802461cd5ba8545e82c64fbd177452b"
+
+PV = "xilinx+git${SRCPV}"
+
+XSCTH_BUILD_CONFIG = ""
+YAML_COMPILER_FLAGS = ""
+XSCTH_APP = "device-tree"
+
+YAML_MAIN_MEMORY_CONFIG_zcu100-zynqmp = "psu_ddr_0"
+YAML_CONSOLE_DEVICE_CONFIG_zcu100-zynqmp = "psu_uart_1"
+
+YAML_DT_BOARD_FLAGS_zcu100-zynqmp = "{BOARD zcu100-revc}"
+YAML_DT_BOARD_FLAGS_zcu102-zynqmp = "{BOARD zcu102-rev1.0}"
+YAML_DT_BOARD_FLAGS_zcu106-zynqmp = "{BOARD zcu106-reva}"
+YAML_DT_BOARD_FLAGS_zc702-zynq7 = "{BOARD zc702}"
+YAML_DT_BOARD_FLAGS_zc706-zynq7 = "{BOARD zc706}"
+YAML_DT_BOARD_FLAGS_zedboard-zynq7 = "{BOARD zedboard}"
+YAML_DT_BOARD_FLAGS_zc1254-zynqmp = "{BOARD zc1254-reva}"
+
+DTS_FILES_PATH = "${XSCTH_WS}/${XSCTH_PROJ}"
+DTS_INCLUDE_append = " ${WORKDIR}"
+DT_PADDING_SIZE = "0x1000"
+KERNEL_DTS_INCLUDE_append = " ${STAGING_KERNEL_DIR}/include"
+
+COMPATIBLE_MACHINE_zynq = ".*"
+COMPATIBLE_MACHINE_zynqmp = ".*"
+
+do_compile_prepend() {
+	[ -e ${DTS_FILES_PATH}/system.dts ] && rm ${DTS_FILES_PATH}/system.dts
+}
+
-- 
2.7.4