[meta-xilinx] [meta-xilinx-contrib][PATCH 3/3 v3] minized-zynq7: Add wireless support

[Clement Laigle]

The Minized has a wireless connectivity (WiFi / Bluetooth). This recipes add drivers to use the murata wireless module.

Signed-off-by: Clement Laigle <clement.laigle8 at gmail.com>
---

Changes in v2:
	- split patch

Changes in v3:
	- Modify partition QSPI
	- Remove unnecessary recipes
	- Fix Licence

---
 .../minized-wireless/minized-wireless.bb           | 43 ++++++++++++++++++++++
 .../linux/linux-xlnx/v2018.1/wifi-bluetooth.cfg    | 33 ++++++++++++++++++++++
 .../linux/linux-xlnx_2018.1.bbappend               |  1 +
 3 file changed, 77 insertions(+)
 create mode 100644 meta-xilinx-contrib/recipes-bsp/minized-wireless/minized-wireless.bb
 create mode 100644 meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx/v2018.1/wifi-bluetooth.cfg

diff --git a/meta-xilinx-contrib/recipes-bsp/minized-wireless/minized-wireless.bb b/meta-xilinx-contrib/recipes-bsp/minized-wireless/minized-wireless.bb
new file mode 100644
index 0000000..78e618b
--- /dev/null
+++ b/meta-xilinx-contrib/recipes-bsp/minized-wireless/minized-wireless.bb
@@ -0,0 +1,43 @@
+SUMMARY = "minized-wireless:  Wi-Fi/BT drivers and firmware for the Murata 1DX module"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://cyw-fmac-fw/LICENCE.cypress;md5=cbc5f665d04f741f1e006d2096236ba7"
+
+SRC_URI = " \
+	git://github.com/murata-wireless/cyw-fmac-fw;protocol=git;branch=orga;destsuffix=cyw-fmac-fw;name=cyw-fmac-fw \
+	git://github.com/murata-wireless/cyw-fmac-nvram;protocol=git;branch=orga;destsuffix=cyw-fmac-nvram;name=cyw-fmac-nvram \
+	git://github.com/murata-wireless/cyw-bt-patch;protocol=git;branch=morty-orga;destsuffix=cyw-bt-patch;name=cyw-bt-patch \
+	git://github.com/murata-wireless/cyw-fmac-utils-imx32;protocol=git;branch=orga;destsuffix=cyw-fmac-utils-imx32;name=cyw-fmac-utils-imx32 \
+"
+
+SRCREV_cyw-fmac-fw = "2242fd3f67a913fbfff8678cc8f7761629dca8ca"
+SRCREV_cyw-fmac-nvram = "d12c2ac1b93941eaa03063bb7cb3c1ee1aa1b7d0"
+SRCREV_cyw-bt-patch = "9216e0d9f778009b5667d032886dfd49174c4b3a"
+SRCREV_cyw-fmac-utils-imx32 = "060688dfe76df98751207c8146268ce7fd80b6ab"
+
+DEPENDS = "libnl virtual/kernel"
+
+S = "${WORKDIR}"
+
+do_install() {
+	install -d ${D}/lib/firmware/brcm
+	install -d ${D}${sysconfdir}/firmware
+	install -d ${D}${bindir}
+
+	install -m 644 ${S}/cyw-fmac-fw/brcmfmac43430-sdio.bin ${D}/lib/firmware/brcm/brcmfmac43430-sdio.bin
+	install -m 644 ${S}/cyw-fmac-nvram/brcmfmac43430-sdio.txt ${D}/lib/firmware/brcm/brcmfmac43430-sdio.txt
+	install -m 644 ${S}/cyw-bt-patch/CYW43430A1.1DX.hcd ${D}${sysconfdir}/firmware/BCM43430A1.1DX.hcd
+	install -m 755 ${S}/cyw-fmac-utils-imx32/wl ${D}${bindir}/wl
+}
+
+PACKAGES =+ "${PN}-mfgtest"
+
+FILES_${PN} = " \
+	/lib/firmware/brcm/brcmfmac43430-sdio.bin \
+	/lib/firmware/brcm/brcmfmac43430-sdio.txt \
+	${sysconfdir}/firmware/BCM43430A1.1DX.hcd \
+"
+
+FILES_${PN}-mfgtest = " \
+	${bindir}/wl \
+"
+
diff --git a/meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx/v2018.1/wifi-bluetooth.cfg b/meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx/v2018.1/wifi-bluetooth.cfg
new file mode 100644
index 0000000..f71e53a
--- /dev/null
+++ b/meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx/v2018.1/wifi-bluetooth.cfg
@@ -0,0 +1,33 @@
+#
+# Bluetooth config
+#
+CONFIG_BT=y
+CONFIG_BT_BREDR=y
+CONFIG_BT_HS=y
+CONFIG_BT_LE=y
+CONFIG_BT_BCM=y
+CONFIG_BT_HCIUART=y
+CONFIG_BT_HCIUART_H4=y
+CONFIG_BT_HCIUART_BCM=y
+CONFIG_BT_HIDP=y
+CONFIG_CFG80211=y
+CONFIG_CFG80211_DEFAULT_PS=y
+CONFIG_CFG80211_CRDA_SUPPORT=y
+CONFIG_BRCMUTIL=y
+CONFIG_BRCMFMAC=y
+CONFIG_BRCMFMAC_PROTO_BCDC=y
+CONFIG_BRCMFMAC_SDIO=y
+CONFIG_CRYPTO_BLKCIPHER=y
+CONFIG_CRYPTO_MANAGER=y
+CONFIG_CRYPTO_ECB=y
+CONFIG_CRYPTO_CMAC=y
+CONFIG_CRYPTO_SHA256=y
+
+#
+# Regulator config
+#
+CONFIG_REGMAP_IRQ=y
+CONFIG_I2C_XILINX=y
+CONFIG_MFD_DA9062=y
+CONFIG_REGULATOR_DA9062=y
+
diff --git a/meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx_2018.1.bbappend b/meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx_2018.1.bbappend
index 83b08f1..48ff77a 100644
--- a/meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx_2018.1.bbappend
+++ b/meta-xilinx-contrib/recipes-kernel/linux/linux-xlnx_2018.1.bbappend
@@ -6,3 +6,4 @@ SRC_URI_append_zybo-linux-bd-zynq7 = " \
 	file://0003-drm-xilinx-Fix-DPMS-transition-to-on.patch \
 	"
 
+SRC_URI_append_minized-zynq7 = " file://wifi-bluetooth.cfg"
-- 
2.7.4