[poky] [PATCH 04/11] mesa-dri: upgrade from 7.8.2 to 7.9

[Yu Ke]

with the following changes:

- remove mesa-demos, because starting from mesa 7.9,
  mesa-demos becomes a standalone src tar ball in
  upstream, so there will be a seperate recipes to
  build the mesa-demos

- add dependency of talloc and libxml2-native

Signed-off-by: Yu Ke <ke.yu at intel.com>
---
 .../distro/include/preferred-xorg-versions.inc     |    2 +-
 meta/recipes-graphics/mesa/mesa-dri_7.8.2.bb       |   53 --------------------
 meta/recipes-graphics/mesa/mesa-dri_7.9.bb         |   38 ++++++++++++++
 3 files changed, 39 insertions(+), 54 deletions(-)
 delete mode 100644 meta/recipes-graphics/mesa/mesa-dri_7.8.2.bb
 create mode 100644 meta/recipes-graphics/mesa/mesa-dri_7.9.bb

diff --git a/meta/conf/distro/include/preferred-xorg-versions.inc b/meta/conf/distro/include/preferred-xorg-versions.inc
index eaea3d6..703d3a6 100644
--- a/meta/conf/distro/include/preferred-xorg-versions.inc
+++ b/meta/conf/distro/include/preferred-xorg-versions.inc
@@ -136,7 +136,7 @@ PREFERRED_VERSION_xtrans-native ?= "1.2.5"
 PREFERRED_VERSION_xtrans-nativesdk ?= "1.2.5"
 PREFERRED_VERSION_xvinfo ?= "1.0.2"
 PREFERRED_VERSION_xwininfo ?= "1.1.0"
-PREFERRED_VERSION_mesa-dri ?= "7.8.2"
+PREFERRED_VERSION_mesa-dri ?= "7.9"
 PREFERRED_VERSION_libdrm ?= "2.4.22"
 PREFERRED_VERSION_xcb-proto ?= "1.6"
 PREFERRED_VERSION_libxcb ?= "1.6"
diff --git a/meta/recipes-graphics/mesa/mesa-dri_7.8.2.bb b/meta/recipes-graphics/mesa/mesa-dri_7.8.2.bb
deleted file mode 100644
index caa9b2e..0000000
--- a/meta/recipes-graphics/mesa/mesa-dri_7.8.2.bb
+++ /dev/null
@@ -1,53 +0,0 @@
-include mesa-common.inc
-
-LIC_FILES_CHKSUM = "file://docs/license.html;md5=7a3373c039b6b925c427755a4f779c1d"
-
-PROTO_DEPS = "xf86driproto glproto dri2proto"
-LIB_DEPS = "libdrm virtual/libx11 libxext libxxf86vm libxdamage libxfixes expat"
-
-DEPENDS = "${PROTO_DEPS}  ${LIB_DEPS} mesa-dri-glsl-native"
-
-PR = "r2"
-
-SRC_URI += "file://crossfix.patch"
-
-# most of our targets do not have DRI so will use mesa-xlib
-DEFAULT_PREFERENCE = "-1"
-
-# Atom PCs have DRI support so use mesa-dri by default
-DEFAULT_PREFERENCE_atom-pc = "1"
-
-LEAD_SONAME = "libGL.so.1"
-
-EXTRA_OECONF += "--with-driver=dri --disable-egl --disable-gallium"
-
-# We need glsl-compile built for buildhost arch instead of target (is provided by mesa-dri-glsl-native)"
-do_configure_prepend() {
-	sed -i "s#^GLSL_CL = .*\$#GLSL_CL = ${STAGING_BINDIR_NATIVE}/glsl-compile#g" ${S}/src/mesa/shader/slang/library/Makefile
-}
-
-do_install_append () {
-	install -d ${D}/usr/bin
-	install -m 0755 ${S}/progs/xdemos/{glxdemo,glxgears,glxheads,glxinfo} ${D}/usr/bin/
-}
-
-python populate_packages_prepend() {
-	import os.path
-
-	dri_drivers_root = os.path.join(bb.data.getVar('libdir', d, 1), "dri")
-
-	do_split_packages(d, dri_drivers_root, '^(.*)_dri\.so$', 'mesa-dri-driver-%s', 'Mesa %s DRI driver', extra_depends='')
-}
-
-COMPATIBLE_HOST = '(i.86.*-linux|x86_64.*-linux)'
-
-PACKAGES =+ "${PN}-xprogs"
-PACKAGES_DYNAMIC = "mesa-dri-driver-*"
-
-FILES_${PN}-dbg += "${libdir}/dri/.debug/*"
-FILES_${PN}-xprogs = "${bindir}/glxdemo ${bindir}/glxgears ${bindir}/glxheads ${bindir}/glxinfo"
-
-#
-# Header generated by i586-poky-linux-gcc gen_matypes.c -o gen_matypes -I ../../../include/GL -I ../../../include -I .. -I ../main/ -I ../math -I ../glapi/ -I ../tnl
-# then run gen_matypes > matypes.h on device
-#
diff --git a/meta/recipes-graphics/mesa/mesa-dri_7.9.bb b/meta/recipes-graphics/mesa/mesa-dri_7.9.bb
new file mode 100644
index 0000000..6f0f984
--- /dev/null
+++ b/meta/recipes-graphics/mesa/mesa-dri_7.9.bb
@@ -0,0 +1,38 @@
+include mesa-common.inc
+
+LIC_FILES_CHKSUM = "file://docs/license.html;md5=7a3373c039b6b925c427755a4f779c1d"
+
+PROTO_DEPS = "xf86driproto glproto dri2proto"
+LIB_DEPS = "libdrm virtual/libx11 libxext libxxf86vm libxdamage libxfixes expat \
+            libxml2-native talloc"
+
+DEPENDS = "${PROTO_DEPS}  ${LIB_DEPS} mesa-dri-glsl-native"
+
+PR = "r0"
+
+SRC_URI = "ftp://ftp.freedesktop.org/pub/mesa/${PV}/MesaLib-${PV}.tar.bz2 \
+           file://crossfix.patch"
+
+# most of our targets do not have DRI so will use mesa-xlib
+DEFAULT_PREFERENCE = "-1"
+
+# Atom PCs have DRI support so use mesa-dri by default
+DEFAULT_PREFERENCE_atom-pc = "1"
+
+LEAD_SONAME = "libGL.so.1"
+
+EXTRA_OECONF += "--with-driver=dri --disable-egl --disable-gallium"
+
+python populate_packages_prepend() {
+	import os.path
+
+	dri_drivers_root = os.path.join(bb.data.getVar('libdir', d, 1), "dri")
+
+	do_split_packages(d, dri_drivers_root, '^(.*)_dri\.so$', 'mesa-dri-driver-%s', 'Mesa %s DRI driver', extra_depends='')
+}
+
+COMPATIBLE_HOST = '(i.86.*-linux|x86_64.*-linux)'
+
+PACKAGES_DYNAMIC = "mesa-dri-driver-*"
+
+FILES_${PN}-dbg += "${libdir}/dri/.debug/*"
-- 
1.7.0.4