[poky] [PATCH 1/3] groff: update to 1.20.1

[Saul Wold]

On 04/27/2011 02:30 AM, Kang Kai wrote:
> From: Kang Kai<kai.kang at windriver.com>
>
> Update groff to 1.20.1, add SUMMARY and LICENSE info
>> From OE 70bf94cd8669f549ca90581e9592d409b6e24e2e
> Fixes [Yocto 879]
>
Why did you not updated the existing recipe, via a git mv and then edit 
it.  We do not keep older recipes around, so they should be cleaned up.

Also, why do we need a native for this recipe?  For dealing with 
documentation native side?

Sau!

> Signed-off-by: Kang Kai<kai.kang at windriver.com>
> ---
>   meta/recipes-extended/groff/groff_1.20.1.bb |   36 +++++++++++++++++++++++++++
>   1 files changed, 36 insertions(+), 0 deletions(-)
>   create mode 100644 meta/recipes-extended/groff/groff_1.20.1.bb
>
> diff --git a/meta/recipes-extended/groff/groff_1.20.1.bb b/meta/recipes-extended/groff/groff_1.20.1.bb
> new file mode 100644
> index 0000000..e0e198f
> --- /dev/null
> +++ b/meta/recipes-extended/groff/groff_1.20.1.bb
> @@ -0,0 +1,36 @@
> +SUMMARY = "GNU Troff software"
> +DESCRIPTION = "The groff (GNU troff) software is a typesetting package which reads plain text mixed with \
> +formatting commands and produces formatted output."
> +SECTION = "base"
> +HOMEPAGE = "ftp://ftp.gnu.org/gnu/groff/"
> +LICENSE = "GPLv2"
> +PR = "r0"
> +
> +LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
> +
> +SRC_URI = "${GNU_MIRROR}/groff/groff-${PV}.tar.gz"
> +
> +SRC_URI[md5sum] = "48fa768dd6fdeb7968041dd5ae8e2b02"
> +SRC_URI[sha256sum] = "b645878135cb620c6c417c5601bfe96172245af12045540d7344938b4c2cd805"
> +
> +DEPENDS = "groff-native"
> +DEPENDS_virtclass-native = ""
> +
> +inherit autotools
> +
> +PARALLEL_MAKE = ""
> +
> +do_configure_prepend() {
> +	if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
> +		sed -i \
> +		    -e '/^GROFFBIN=/s:=.*:=${STAGING_BINDIR_NATIVE}/groff:' \
> +		    -e '/^TROFFBIN=/s:=.*:=${STAGING_BINDIR_NATIVE}/troff:' \
> +		    -e '/^GROFF_BIN_PATH=/s:=.*:=${STAGING_BINDIR_NATIVE}:' \
> +		    -e '/^GROFF_BIN_DIR=/s:=.*:=${STAGING_BINDIR_NATIVE}:' \
> +		    ${S}/contrib/*/Makefile.sub \
> +		    ${S}/doc/Makefile.in \
> +		    ${S}/doc/Makefile.sub
> +	fi
> +}
> +
> +BBCLASSEXTEND = "native"